source: configure.in @ e3fa533

cachetimestampsdevelopdpdk-ndagetsiliverc-4.0.2rc-4.0.3rc-4.0.4ringdecrementfixringperformance
Last change on this file since e3fa533 was e3fa533, checked in by Shane Alcock <salcock@…>, 3 years ago

Bump version number to 4.0.2

  • Property mode set to 100644
File size: 21.9 KB
Line 
1# Process this file with autoconf to produce a configure script.
2
3# Now you only need to update the version number in two places - below,
4# and in the README
5
6AC_INIT([libtrace],[4.0.2],[contact@wand.net.nz],[libtrace])
7
8LIBTRACE_MAJOR=4
9LIBTRACE_MID=0
10LIBTRACE_MINOR=2
11
12# OpenSolaris hides libraries like libncurses in /usr/gnu/lib, which is not
13# searched by default - add it to LDFLAGS so we at least have a chance of
14# finding it
15if test -d "/usr/gnu/lib"; then
16        LDFLAGS+=" -L/usr/gnu/lib"
17fi
18
19AC_CONFIG_MACRO_DIR([m4])
20AC_CONFIG_SRCDIR(lib/trace.c)
21AM_INIT_AUTOMAKE([subdir-objects])
22
23# Make sure we use the relatively silent automake output
24m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
25
26# Define our libtrace version number externally so we can use it in the source
27# as well, if needed.
28AC_DEFINE([LIBTRACE_MAJOR],${LIBTRACE_MAJOR},[libtrace major version])
29AC_DEFINE([LIBTRACE_MID],${LIBTRACE_MID},[libtrace mid version])
30AC_DEFINE([LIBTRACE_MINOR],${LIBTRACE_MINOR},[libtrace minor version])
31
32# These are all the files we want to be built for us by configure
33AC_CONFIG_FILES([Makefile lib/Makefile docs/Makefile libpacketdump/Makefile
34        tools/Makefile tools/traceanon/Makefile tools/tracepktdump/Makefile
35        tools/tracemerge/Makefile tools/tracereport/Makefile
36        tools/tracertstats/Makefile tools/tracesplit/Makefile
37        tools/tracestats/Makefile tools/tracetop/Makefile
38        tools/tracereplay/Makefile tools/tracediff/Makefile
39        tools/traceends/Makefile
40        examples/Makefile examples/skeleton/Makefile examples/rate/Makefile
41        examples/stats/Makefile examples/tutorial/Makefile examples/parallel/Makefile
42        docs/libtrace.doxygen
43        lib/libtrace.h
44        ])
45
46
47# Function that checks if the C++ compiler actually works - there's a bit of
48# oversight in autoconf that will set the C++ compiler to g++ if no compiler
49# is found, even if g++ is not present! So we need an extra test to make sure
50# that the compiler works :(
51
52AC_DEFUN([rw_PROG_CXX_WORKS],
53[AC_REQUIRE([AC_PROG_CXX])dnl
54AC_CACHE_CHECK([whether the C++ compiler works],
55        [rw_cv_prog_cxx_works],
56        [AC_LANG_PUSH([C++])
57        AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
58                [rw_cv_prog_cxx_works=yes],
59                [rw_cv_prog_cxx_works=no])
60        AC_LANG_POP([C++])])
61])
62
63# Put all our automake definitions in config.h
64AM_CONFIG_HEADER([config.h])
65
66# Checks for C and C++ compilers
67AC_PROG_CC
68AC_PROG_CXX
69rw_PROG_CXX_WORKS
70
71if test "$rw_cv_prog_cxx_works" = "no"; then
72        AC_MSG_ERROR("Failed to find working C++ compiler")
73fi
74
75# Checking for 'install'
76AC_PROG_INSTALL
77
78# Checking for bison and flex
79AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc)
80AM_PROG_LEX
81
82# All our source files for function replacements are in lib/
83AC_CONFIG_LIBOBJ_DIR(lib)
84
85# Check for various "replacement" functions
86AC_FUNC_MALLOC
87AC_FUNC_REALLOC
88
89# *BSD doesn't have strndup. Currently provide our own.
90AC_REPLACE_FUNCS(strndup)
91
92
93# Checks for typedefs, structures, and compiler characteristics.
94AC_C_CONST
95AC_C_INLINE
96AC_C_BIGENDIAN
97AC_TYPE_SIZE_T
98AC_HEADER_TIME
99AC_SYS_LARGEFILE
100
101LIBPKTDUMP_LIBS="-ltrace "
102ADD_LDFLAGS="$ADD_LDFLAGS -L\$(abs_top_srcdir)/lib"
103LIBTRACE_LIBS=""
104TOOLS_LIBS=""
105
106CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wextra -DLT_BUILDING_DLL=1"
107CXXFLAGS="$CXXFLAGS -Wall -DLT_BUILDING_DLL=1"
108
109# Check for -fvisibility
110gl_VISIBILITY
111
112gcc_PACKED
113gcc_DEPRECATED
114gcc_UNUSED
115gcc_PURE
116gcc_FORMAT
117
118# Check for gcc style TLS (__thread)
119gcc_TLS
120       
121# Check for libtool
122AC_PROG_LIBTOOL
123
124# Checks for library functions.
125AC_PROG_GCC_TRADITIONAL
126
127# Fail if any of these functions are missing
128AC_CHECK_FUNCS(socket strdup strlcpy strcasecmp strncasecmp snprintf vsnprintf)
129
130AC_CHECK_SIZEOF([long int])
131
132
133# Checks for header files.
134AC_HEADER_STDC
135AC_CHECK_HEADERS(pcap.h pcap-int.h pcap-bpf.h net/bpf.h sys/limits.h stddef.h inttypes.h limits.h net/ethernet.h sys/prctl.h)
136
137
138# OpenSolaris puts ncurses.h in /usr/include/ncurses rather than /usr/include,
139# so check for that
140AC_CHECK_HEADERS(ncurses.h,,[missing_ncurses=true])
141
142if test "x$missing_ncurses" = xtrue; then
143        if test -f "/usr/include/ncurses/ncurses.h"; then
144                AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Has nested ncurses header])
145        fi
146fi
147
148
149# Check for the presence of various networking headers and define appropriate
150# macros
151AC_CHECK_HEADERS(netinet/in.h)
152AC_CHECK_HEADERS(netpacket/packet.h,[
153        libtrace_netpacket_packet_h=true
154        AC_DEFINE(HAVE_NETPACKET_PACKET_H,1,[has net])
155])
156AC_CHECK_HEADER(net/if.h,
157        AC_DEFINE(HAVE_NET_IF_H,1,[has net/if.h header]),,[
158 #include <sys/types.h>
159 #include <sys/socket.h>
160])
161
162AC_CHECK_HEADER(netinet/ether.h,
163        AC_DEFINE(HAVE_NETINET_ETHER_H,1,[has netinet/ether.h header]),,[
164 #include <sys/types.h>
165 #include <sys/socket.h>
166 #include <netinet/in.h>
167 #include <net/if.h>
168])
169
170AC_CHECK_HEADER(netinet/if_ether.h,
171        AC_DEFINE(HAVE_NETINET_IF_ETHER_H,1,[has netinet/if_ether.h]),,[
172 #include <sys/types.h>
173 #include <sys/socket.h>
174 #include <netinet/in.h>
175 #include <net/if.h>
176])
177
178AC_CHECK_HEADER(net/if_arp.h,
179        AC_DEFINE(HAVE_NET_IF_ARP_H,1,[has net/if_arp.h]),,[
180 #include <sys/types.h>
181 #include <sys/socket.h>
182 #include <netinet/in.h>
183 #include <net/if.h>
184])
185
186# Check for sdl_len in sockaddr_dl - sockaddr_dl is used on BSD systems
187if test "$libtrace_netpacket_packet_h" != "true"; then
188        AC_CHECK_MEMBER([struct sockaddr_dl.sdl_len],
189                AC_DEFINE(HAVE_SDL_LEN,1,[Has sdl_len in sockaddr_dl]),,[
190 #include <sys/types.h>
191 #include <sys/socket.h>
192 #include <net/if_dl.h>
193                ])
194fi
195
196# Checking for the right bpf header to include
197AC_CHECK_HEADER(pcap-bpf.h)
198AC_CHECK_HEADER(net/bpf.h)
199
200# Checking for libgdc
201AC_CHECK_HEADER(gdc.h,AC_DEFINE(HAVE_LIBGDC,1,[has gdc.h]))
202
203# Check for libwandio (no longer bundled with libtrace)
204AC_CHECK_LIB(wandio,wandio_create,wandiofound=1,wandiofound=0)
205if test "$wandiofound" = 0; then
206        AC_MSG_ERROR(libwandio is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library. WANDIO can be obtained from http://research.wand.net.nz/software/libwandio.php)
207else
208        LIBTRACE_LIBS="$LIBTRACE_LIBS -lwandio"
209        TOOLS_LIBS="$TOOLS_LIBS -lwandio"
210        AC_DEFINE([HAVE_LIBWANDIO],1,[compile with libwandio support])
211fi
212
213AC_CHECK_LIB(crypto, EVP_EncryptInit_ex, cryptofound=1, cryptofound=0)
214
215# Check for libpcap
216AC_CHECK_LIB(pcap,pcap_next_ex,pcapfound=1,pcapfound=0)
217AC_CHECK_LIB(pcap,pcap_create,pcapcreate=1,pcapcreate=0)
218AC_CHECK_LIB(pcap,pcap_set_immediate_mode,pcapimmediate=1,pcapimmediate=0)
219AC_CHECK_DECLS([BIOCSETIF],,,[
220#include <sys/types.h>
221#include <sys/time.h>
222#include <sys/ioctl.h>
223#include <net/bpf.h>
224])
225
226AC_ARG_ENABLE(memory-debugging,
227                AS_HELP_STRING(--enable-memory-debugging, prints internal memory statistics),[
228                if test "$HAVE_TLS" = 1
229                then
230                    AC_DEFINE([ENABLE_MEM_STATS], 1, [print debug memory statistics])
231                fi
232],[])
233
234# Configure options for man pages
235AC_ARG_WITH(man,
236            AS_HELP_STRING(--with-man,install man pages by default),[
237             if test "$withval" = yes
238             then
239                     MANPAGES="docs/man/man3/[a-zA-Z]*.3"
240             else
241                     MANPAGES=""
242             fi
243])
244
245# Complain if we didn't find a suitable libpcap
246if test "$pcapfound" = 0; then
247        AC_MSG_ERROR(libpcap0.8 or greater is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library)
248else
249        TOOL_LIBS="$TOOL_LIBS -lpcap"
250        LIBTRACE_LIBS="$LIBTRACE_LIBS -lpcap"
251        AC_DEFINE([HAVE_LIBPCAP],1,[compile with libpcap support])
252
253        LIBS="-lpcap"
254        AC_CHECK_FUNCS(pcap_inject pcap_sendpacket pcap_setnonblock)
255        LIBS=""
256
257fi
258
259if test "$pcapcreate" = 1; then
260        AC_DEFINE([HAVE_PCAP_CREATE],1,[compile with libpcap 1.0 support])
261fi
262
263if test "$pcapimmediate" = 1; then
264        AC_DEFINE([HAVE_PCAP_IMMEDIATE],1,[able to use pcap_set_immediate_mode])
265fi       
266
267# Configure options for use of DAG cards
268# Originally borrowed from libpcap, but extended quite a bit :)
269# More details on how this check works:
270#       http://wand.net.nz/trac/libtrace/wiki/DAGNotes
271
272AC_ARG_WITH(dag,
273            AS_HELP_STRING(--with-dag[=DIR],include DAG live capture support (located in directory DIR, if supplied)),
274[
275        if test "$withval" = no
276        then
277                want_dag=no
278        elif test "$withval" = yes
279        then
280                want_dag=yes
281                dag_root=/usr/local/dag
282        else
283                want_dag=yes
284                dag_root=$withval
285        fi
286],[
287        #
288        # Use DAG API if present, otherwise don't
289        #
290        want_dag=ifpresent
291        dag_root=/usr/local/dag
292])
293
294# DAG 3.0 actually puts header files and shared libraries into sensible
295# places now, so we should be able to do a simple CHECK_LIB to see if
296# they're there!
297
298# Addendum: It turns out DAG 2.5 does this too, so we'll match DAG2.5 in here
299# also. This isn't such a bad thing, the DAG2.5 API is essentially the same as
300# DAG 3.0 and libtrace will use the same format_dagXX source for both
301libtrace_dag=false
302libtrace_dag_version=none
303
304if test "$with_dag" != no; then
305        AC_CHECK_LIB(dag, dag_open, dag_found=1, dag_found=0)
306        if test "$dag_found" = 1; then
307                ADD_LIBS="$ADD_LIBS -ldag"
308                LIBTRACE_LIBS="$LIBTRACE_LIBS -ldag"
309                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
310                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
311                libtrace_dag=true
312               
313                AC_DEFINE(DAG_VERSION,25,[defines the DAG driver version])
314                libtrace_dag_version=25
315
316                AC_CHECK_HEADERS(dag_config_api.h,[csapi_found=1],,)
317                if test "$csapi_found" = 1; then
318                        LIBTRACE_LIBS="$LIBTRACE_LIBS -ldagconf"
319                fi
320        fi     
321fi
322
323# TODO: turn the test part of the next block into a function, so it can be
324# called multiple times for $dag_root, /root/dag, /usr/local/lib
325dag_drv_v="DAG not present"
326
327# Now check for 2.4 DAG drivers which don't install as cleanly!
328if test "$with_dag" != no -a "$libtrace_dag" = false; then
329        AC_MSG_CHECKING(whether we have DAG 2.4 API instead)
330
331        if test -r "$dag_root/lib"; then
332                dag_lib_dir="$dag_root/lib"
333        else
334                dag_lib_dir="$dag_root"
335        fi
336       
337        if test -r "$dag_root/include"; then
338                dag_tools_dir="$dag_root/tools"
339                dag_include_dir="$dag_root/include"
340        else
341                dag_tools_dir="$dag_root"
342                dag_include_dir="$dag_root"
343        fi
344
345        if test -r "$dag_include_dir/dagapi.h" -a -r "$dag_lib_dir/libdag.a";
346        then
347                ADD_INCLS="$ADD_INCLS -I $dag_include_dir"
348                ADD_LIBS="$ADD_LIBS -ldag"
349                ADD_LDFLAGS="$ADD_LDFLAGS -L$dag_lib_dir"
350                DAG_TOOLS_DIR=$dag_tools_dir
351                AC_SUBST([DAG_TOOLS_DIR])
352                libtrace_dag=true
353               
354                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
355                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
356                AC_DEFINE(DAG_VERSION, 24, [defines the DAG driver version])
357                libtrace_dag_version=24
358        else
359                if test "$want_dag" = yes; then
360                        AC_MSG_ERROR(DAG API not found under directory $dag_root
361; use --without-dag)
362                fi
363                libtrace_dag=false
364        fi
365        AC_MSG_RESULT($libtrace_dag)
366
367fi
368
369# Try to determine the DAG driver version
370#if test x"$libtrace_dag" = xtrue; then
371#       dag_drv_v="Unknown"
372#       files=`locate /usr/*dag*/VERSION`
373#       file_count=0
374#
375#       for i in $files; do
376#                if $file_count > 0; then
377#                        dag_drv_v="Indeterminate"
378#                        break
379#                fi
380#                dag_drv_v=`cat $i`
381#                file_count=$file_count+1
382#        done
383#fi
384#DAG_VERSION_NUM=$dag_drv_v
385
386# Check for DPDK
387AC_ARG_WITH(dpdk,
388            AS_HELP_STRING(--with-dpdk,include DPDK live capture support (From either the RTE_SDK/_TARGET environment variable or the dpdk-dev package)),
389[
390        if test "$withval" = no
391        then
392            want_dpdk=no
393        else
394            want_dpdk=ifpresent
395        fi
396],[
397        # Default to building without DPDK format
398        want_dpdk=no
399])
400
401libtrace_dpdk=false
402if test "$want_dpdk" != no; then
403        # So instead simply check for existence
404        if test "$RTE_SDK" != ""; then
405                AC_CHECK_FILE("$RTE_SDK/$RTE_TARGET/lib/libintel_dpdk.a", dpdk_found="libintel_dpdk.a", dpdk_found=0)
406        fi
407        # DPDK 2.1.0+ renames this to libdpdk from libintel_dpdk
408        if test "$dpdk_found" = 0 -a "$RTE_SDK" != ""; then
409                AC_CHECK_FILE("$RTE_SDK/$RTE_TARGET/lib/libdpdk.a", dpdk_found="libdpdk.a", dpdk_found=0)
410        fi
411        if test "$dpdk_found" != 0 -a "$RTE_SDK" != ""; then
412                # Save these now so that they can be re-exported later
413                AC_SUBST([RTE_TARGET])
414                AC_SUBST([RTE_SDK])
415                # Force dpdk library to be statically linked to allow compiler optimisations
416                LIBTRACE_LIBS="$LIBTRACE_LIBS -Wl,--whole-archive -Wl,-l:$dpdk_found -Wl,--no-whole-archive -Wl,-lm"
417                AC_DEFINE(HAVE_DPDK,1,[conditional for building with DPDK live capture support])
418                libtrace_dpdk=true
419        fi
420        if test "$RTE_SDK" = ""; then
421                AC_MSG_NOTICE([No RTE_SDK given, checking for system dpdk-dev package])
422                # Search the system, maybe it is installed? Ethdev is one of the main libraries
423                AC_CHECK_LIB(ethdev, rte_eth_dev_configure, dpdk_found="system", dpdk_found=0)
424                # We also need to check that rte.vars.mk is installed from dpdk-dev (as well as libdpdk-dev)
425                if test "$dpdk_found" != 0 -a -e /usr/share/dpdk/mk/rte.vars.mk ; then
426                        RTE_TARGET="x86_64-default-linuxapp-gcc"
427                        RTE_SDK="/usr/share/dpdk/"
428                        RTE_INCLUDE="/usr/include/dpdk"
429                        AC_SUBST([RTE_TARGET])
430                        AC_SUBST([RTE_SDK])
431                        AC_SUBST([RTE_INCLUDE])
432                        # include libethdev this is part of DPDK
433                        LIBTRACE_LIBS="$LIBTRACE_LIBS -lethdev"
434                        # Include all rte libs note we need to escape '[' and ']'
435                        LIBTRACE_LIBS="$LIBTRACE_LIBS $(ldconfig -p | sed 's/.*lib\([[^.]]*\).*/-l\1/' | grep rte_ | tr '\n' ' ')"
436                        AC_MSG_NOTICE([Building against system DPDK])
437
438                        AC_DEFINE(HAVE_DPDK,1,[conditional for building with DPDK live capture support])
439                        libtrace_dpdk=true
440                fi
441        fi
442fi
443
444# Check for PACKET_FANOUT (borrowed from Suricata)
445AC_CHECK_DECL([PACKET_FANOUT],
446        AC_DEFINE([HAVE_PACKET_FANOUT],[1],
447        [Recent packet fanout support is available]),
448        [],
449        [[#include <linux/if_packet.h>]])
450
451# If we use DPDK we might be able to use libnuma
452AC_CHECK_LIB(numa, numa_node_to_cpus, have_numa=1, have_numa=0)
453
454# Checks for various "optional" libraries
455AC_CHECK_LIB(pthread, pthread_create, have_pthread=1, have_pthread=0)
456
457AC_CHECK_LIB(pthread, pthread_setname_np, have_pthread_setname_np=1, have_pthread_setname_np=0)
458
459# Check for ncurses
460
461# These libraries have to be explicitly linked in OpenSolaris
462AC_SEARCH_LIBS(getservent, socket, have_socket=1, have_socket=0, -lnsl)
463LIBS=
464
465AC_SEARCH_LIBS(inet_ntop, nsl, have_nsl=1, have_nsl=0, -lsocket)
466LIBS=
467
468# Check to see if we have libdl - *BSD has built-in libdl
469AC_SEARCH_LIBS(dlopen,dl, dlfound=1,dlfound=0 )
470LIBS=
471
472# Check for clock_gettime
473AC_CHECK_LIB(rt, clock_gettime, have_clock_gettime=1, have_clock_gettime=0)
474LIBS=
475
476if test "$have_numa" = 1; then
477        LIBTRACE_LIBS="$LIBTRACE_LIBS -lnuma"
478        AC_DEFINE(HAVE_LIBNUMA, 1, [Set to 1 if libnuma is supported])
479        with_numa=yes
480else
481        AC_DEFINE(HAVE_LIBNUMA, 0, [Set to 1 if libnuma is supported])
482        with_numa=no
483fi
484
485if test "$dlfound" = 0; then
486        AC_MSG_ERROR("Unable to find dlopen. Please use LDFLAGS to specify the location of libdl and re-run configure")
487fi
488
489if test "$ac_cv_search_dlopen" != "none required"; then
490        LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_dlopen"
491        if test "$dpdk_found" != 0; then
492                LIBTRACE_LIBS="$LIBTRACE_LIBS -Wl,$ac_cv_search_dlopen"
493        fi
494fi
495
496if test "$have_pthread" = 1; then
497        AC_DEFINE(HAVE_LIBPTHREAD, 1, [Set to 1 if pthreads are supported])
498fi
499
500if test "$have_pthread_setname_np" = 1; then
501        AC_DEFINE(HAVE_PTHREAD_SETNAME_NP, 1, [Set to 1 if pthread_setname_np is found])
502fi
503
504if test "$cryptofound" = 1; then
505        AC_DEFINE(HAVE_LIBCRYPTO, 1, [Set to 1 if libcrypto is available])
506        TOOLS_LIBS="$TOOLS_LIBS -lcrypto"
507        have_crypto=yes
508else
509        have_crypto=no
510fi
511
512if test "$have_nsl" = 1; then
513        if test "$ac_cv_search_inet_ntop" != "none required"; then
514                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_inet_ntop"
515                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_inet_ntop"
516        fi
517fi
518
519if test "$have_socket" = 1; then
520        if test "$ac_cv_search_getservent" != "none required"; then
521                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_getservent"
522                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_getservent"
523        fi
524fi
525
526
527if test "$have_clock_gettime" = 1; then
528        LIBTRACE_LIBS="$LIBTRACE_LIBS -lrt"
529        AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Set to 1 if clock_gettime is supported])
530        with_clock_gettime=yes
531else
532        AC_DEFINE(HAVE_CLOCK_GETTIME, 0, [Set to 1 if clock_gettime is supported])
533        with_clock_gettime=no
534fi
535
536
537# Stupid AC_SEARCH_LIB appends stuff to LIBS even when I don't want it to, so
538# just set libs to null here to avoid linking against them by default
539LIBS=
540
541# For now, the user has to explicitly ask for the LLVM stuff, as it's a bit
542# rough around the edges :(
543AC_ARG_WITH([llvm],
544        [AC_HELP_STRING([--with-llvm],
545                [support Just In Time compiler])],
546        use_llvm="yes",
547        use_llvm="no")
548JIT=no
549
550# Search for LLVM and the libraries that it requires
551if (test "$use_llvm" != "no"); then
552        AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
553
554        # XXX Hard coding the path is REALLY bad.
555        # llvm-gcc is installed in a stupid place in Debian / Ubuntu. Hard luck
556        # if you've installed it somewhere custom.
557        # Hopefully in future we can replace this with clang, which may or may
558        # not be installed somewhere intelligent.
559        AC_PATH_PROG(LLVM_GCC, llvm-gcc, no, /usr/lib/llvm/llvm/gcc-4.2/bin)
560
561        AC_LANG_PUSH([C++])
562        AC_CHECK_HEADERS([boost/lexical_cast.hpp], boost="yes", boost="no")
563        AC_LANG_POP([C++])
564
565               
566        if test "$boost" = "no"; then
567                AC_MSG_NOTICE([Unabled to find boost libraries.  JIT support disabled.])
568                JIT=no
569        elif test "$LLVM_CONFIG" = "no" ; then
570                AC_MSG_NOTICE([Unable to find llvm-config.  JIT support disabled.])
571                JIT=no
572        elif test "$LLVM_GCC" = "no"; then
573                AC_MSG_NOTICE([Unable to find llvm-gcc.  JIT support disabled.])
574                JIT=no
575        else
576                LIBCXXFLAGS="`$LLVM_CONFIG --cxxflags` $CXXFLAGS"
577                LIBTRACE_LIBS="$LIBRACE_LIBS `$LLVM_CONFIG --libs all`";
578                LDFLAGS="`$LLVM_CONFIG --ldflags` $LDFLAGS";
579                JIT=yes
580                AC_DEFINE(HAVE_LLVM, 1, [Set to 1 if you have LLVM installed])
581        fi
582fi
583
584AC_ARG_WITH([ncurses],
585        AC_HELP_STRING([--with-ncurses], [build tracetop (requires ncurses)]))
586
587AS_IF([test "x$with_ncurses" != "xno"],
588        [AC_SEARCH_LIBS(mvprintw, ncurses, have_ncurses=yes, have_ncurses=no)
589         LIBS=
590        ], [have_ncurses=no])
591
592AS_IF([test "x$have_ncurses" = "xyes"], [
593        if test "$ac_cv_search_mvprintw" != "none required"; then
594                TOOLS_LIBS="$TOOLS_LIBS $ac_cv_search_mvprintw"
595        fi
596        AC_DEFINE(HAVE_NCURSES, 1, "Compiled with ncurses support")
597        with_ncurses=yes],
598
599       
600        [AS_IF([test "x$with_ncurses" = "xyes"],
601                [AC_MSG_ERROR([ncurses requested but not found])])
602        AC_DEFINE(HAVE_NCURSES, 0, "Compiled with ncurses support")
603        with_ncurses=no]
604)
605
606# Define automake conditionals for use in our Makefile.am files
607AM_CONDITIONAL([HAVE_BPF_CAPTURE], [test "$ac_cv_have_decl_BIOCSETIF" = yes ])
608AM_CONDITIONAL([HAVE_DAG], [test "$libtrace_dag" = true])
609AM_CONDITIONAL([HAVE_DPDK], [test "$libtrace_dpdk" = true])
610AM_CONDITIONAL([DAG2_4], [test "$libtrace_dag_version" = 24])
611AM_CONDITIONAL([DAG2_5], [test "$libtrace_dag_version" = 25])
612AM_CONDITIONAL([HAVE_NETPACKET_PACKET_H], [test "$libtrace_netpacket_packet_h" = true])
613AM_CONDITIONAL([HAVE_LIBGDC], [test "$ac_cv_header_gdc_h" = yes])
614AM_CONDITIONAL([HAVE_LLVM], [test "x$JIT" != "xno" ])
615AM_CONDITIONAL([HAVE_NCURSES], [test "x$with_ncurses" != "xno"])
616
617# Check for miscellaneous programs
618AC_CHECK_PROG([libtrace_doxygen], [doxygen], [true], [false])
619
620AM_CONDITIONAL(HAS_DOXYGEN, [test x"$libtrace_doxygen" = xtrue])
621
622# Set all our output variables
623AC_SUBST([LIBTRACE_LIBS])
624AC_SUBST([LIBPKTDUMP_LIBS])
625AC_SUBST([TOOLS_LIBS])
626#AC_SUBST([ADD_LIBS])
627AC_SUBST([ADD_LDFLAGS])
628AC_SUBST([ADD_INCLS])
629AC_SUBST([LTLIBOBJS])
630AC_SUBST([MANPAGES])
631AC_SUBST([PACKAGE_VERSION])
632AC_SUBST([LIBTRACE_MAJOR])
633AC_SUBST([LIBTRACE_MID])
634AC_SUBST([LIBTRACE_MINOR])
635AC_SUBST([DAG_VERSION_NUM])
636AC_SUBST([HAVE_BPF_CAPTURE])
637AC_SUBST([HAVE_LIBGDC])
638AC_SUBST([HAVE_LLVM])
639AC_SUBST([HAVE_NCURSES])
640AC_SUBST([LIBCFLAGS])
641AC_SUBST([LIBCXXFLAGS])
642
643
644# Finally, output our Makefiles
645AC_OUTPUT
646
647# Function for reporting whether an option was set or not
648reportopt() {
649        if test x"$2" = xtrue -o x"$2" = xyes; then
650                AC_MSG_NOTICE([$1: Yes])
651        else
652                AC_MSG_NOTICE([$1: No])
653        fi
654}
655
656
657# Report which configure options were set
658echo
659AC_MSG_NOTICE([Libtrace version $PACKAGE_VERSION])
660if test "$pcapcreate" = 1; then
661        AC_MSG_NOTICE([Compiled with PCAP support: >= 1.0])
662else
663        AC_MSG_NOTICE([Compiled with PCAP support: < 1.0])
664fi
665
666if test x"$libtrace_dag" = xtrue; then
667        if test "$libtrace_dag_version" = 24; then
668                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.4])
669        elif test "$libtrace_dag_version" = 30; then
670                AC_MSG_NOTICE([Compiled with DAG live capture support: 3.0])
671        else
672                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.5])
673        fi     
674else
675        AC_MSG_NOTICE([Compiled with DAG live capture support: No])
676fi
677
678if test x"$libtrace_dpdk" = xtrue; then
679        AC_MSG_NOTICE([Compiled with DPDK live capture support: Yes])
680        reportopt "Compiled with DPDK trace NUMA support" $with_numa
681        reportopt "Compiled with clock_gettime support" $with_clock_gettime
682elif test x"$want_dpdk" != "xno"; then
683#   We don't officially support DPDK so only report failure if the user
684#   explicitly asked for DPDK. That way, we can hopefully keep it hidden
685#   from most users for now...
686
687        AC_MSG_NOTICE([Compiled with DPDK live capture support: No])
688        AC_MSG_NOTICE([Note: Requires DPDK v1.5 or newer])
689fi
690reportopt "Compiled with LLVM BPF JIT support" $JIT
691reportopt "Building man pages/documentation" $libtrace_doxygen
692reportopt "Building tracetop (requires libncurses)" $with_ncurses
693reportopt "Building traceanon with CryptoPan (requires libcrypto)" $have_crypto
694
695# Report any errors relating to missing bison, flex, etc.
696echo
697ac_cv_errcount=0;
698if test -z "$YACC"; then
699        AC_MSG_WARN(bison or yacc not found. Please install bison before continuing)
700        ac_cv_errcount=$((ac_cv_errcount + 1))
701fi
702
703if test "x$LEX" != xflex -a "x$LEX" != xlex; then
704        AC_MSG_WARN(flex or lex not found. Please install flex before continuing)
705        ac_cv_errcount=$((ac_cv_errcount + 1))
706fi
707
708if test $ac_cv_errcount -gt 0; then
709        AC_MSG_ERROR(Critical packages are missing and compilation will fail. Please install the packages listed above and rerun ./configure)
710fi
711
Note: See TracBrowser for help on using the repository browser.