source: configure.in @ d8b05b7

4.0.1-hotfixescachetimestampsdevelopdpdk-ndagetsilivelibtrace4ndag_formatpfringrc-4.0.1rc-4.0.2rc-4.0.3rc-4.0.4ringdecrementfixringperformanceringtimestampfixes
Last change on this file since d8b05b7 was 32a3ec5, checked in by Shane Alcock <salcock@…>, 6 years ago

Various DAG fixes

  • Use CSAPI for configuring snap length if available
  • Don't die if the number of streams doesn't exactly match the number of processing threads. Instead, just choose the minimum of the two and work with that.
  • Remove debug output re: thread starting
  • Property mode set to 100644
File size: 21.1 KB
Line 
1# Process this file with autoconf to produce a configure script.
2
3# Now you only need to update the version number in two places - below,
4# and in the README
5
6AC_INIT([libtrace],[4.0.0],[contact@wand.net.nz],[libtrace])
7
8LIBTRACE_MAJOR=4
9LIBTRACE_MID=0
10LIBTRACE_MINOR=0
11
12# OpenSolaris hides libraries like libncurses in /usr/gnu/lib, which is not
13# searched by default - add it to LDFLAGS so we at least have a chance of
14# finding it
15if test -d "/usr/gnu/lib"; then
16        LDFLAGS+=" -L/usr/gnu/lib"
17fi
18
19AC_CONFIG_MACRO_DIR([m4])
20AC_CONFIG_SRCDIR(lib/trace.c)
21AM_INIT_AUTOMAKE([subdir-objects])
22
23# Make sure we use the relatively silent automake output
24m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
25
26# Define our libtrace version number externally so we can use it in the source
27# as well, if needed.
28AC_DEFINE([LIBTRACE_MAJOR],${LIBTRACE_MAJOR},[libtrace major version])
29AC_DEFINE([LIBTRACE_MID],${LIBTRACE_MID},[libtrace mid version])
30AC_DEFINE([LIBTRACE_MINOR],${LIBTRACE_MINOR},[libtrace minor version])
31
32# These are all the files we want to be built for us by configure
33AC_CONFIG_FILES([Makefile lib/Makefile docs/Makefile libpacketdump/Makefile
34        tools/Makefile tools/traceanon/Makefile tools/tracepktdump/Makefile
35        tools/tracemerge/Makefile tools/tracereport/Makefile
36        tools/tracertstats/Makefile tools/tracesplit/Makefile
37        tools/tracestats/Makefile tools/tracetop/Makefile
38        tools/tracereplay/Makefile tools/tracediff/Makefile
39        tools/traceends/Makefile
40        examples/Makefile examples/skeleton/Makefile examples/rate/Makefile
41        examples/stats/Makefile examples/tutorial/Makefile examples/parallel/Makefile
42        docs/libtrace.doxygen
43        lib/libtrace.h
44        ])
45
46
47# Function that checks if the C++ compiler actually works - there's a bit of
48# oversight in autoconf that will set the C++ compiler to g++ if no compiler
49# is found, even if g++ is not present! So we need an extra test to make sure
50# that the compiler works :(
51
52AC_DEFUN([rw_PROG_CXX_WORKS],
53[AC_REQUIRE([AC_PROG_CXX])dnl
54AC_CACHE_CHECK([whether the C++ compiler works],
55        [rw_cv_prog_cxx_works],
56        [AC_LANG_PUSH([C++])
57        AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
58                [rw_cv_prog_cxx_works=yes],
59                [rw_cv_prog_cxx_works=no])
60        AC_LANG_POP([C++])])
61])
62
63# Put all our automake definitions in config.h
64AM_CONFIG_HEADER([config.h])
65
66# Checks for C and C++ compilers
67AC_PROG_CC
68AC_PROG_CXX
69rw_PROG_CXX_WORKS
70
71if test "$rw_cv_prog_cxx_works" = "no"; then
72        AC_MSG_ERROR("Failed to find working C++ compiler")
73fi
74
75# Checking for 'install'
76AC_PROG_INSTALL
77
78# Checking for bison and flex
79AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc)
80AM_PROG_LEX
81
82# All our source files for function replacements are in lib/
83AC_CONFIG_LIBOBJ_DIR(lib)
84
85# Check for various "replacement" functions
86AC_FUNC_MALLOC
87AC_FUNC_REALLOC
88
89# *BSD doesn't have strndup. Currently provide our own.
90AC_REPLACE_FUNCS(strndup)
91
92
93# Checks for typedefs, structures, and compiler characteristics.
94AC_C_CONST
95AC_C_INLINE
96AC_C_BIGENDIAN
97AC_TYPE_SIZE_T
98AC_HEADER_TIME
99AC_SYS_LARGEFILE
100
101LIBPKTDUMP_LIBS="-ltrace "
102ADD_LDFLAGS="$ADD_LDFLAGS -L\$(abs_top_srcdir)/lib"
103LIBTRACE_LIBS=""
104TOOLS_LIBS=""
105
106CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wextra -DLT_BUILDING_DLL=1"
107CXXFLAGS="$CXXFLAGS -Wall -DLT_BUILDING_DLL=1"
108
109# Check for -fvisibility
110gl_VISIBILITY
111
112gcc_PACKED
113gcc_DEPRECATED
114gcc_UNUSED
115gcc_PURE
116gcc_FORMAT
117
118# Check for gcc style TLS (__thread)
119gcc_TLS
120       
121# Check for libtool
122AC_PROG_LIBTOOL
123
124# Checks for library functions.
125AC_PROG_GCC_TRADITIONAL
126
127# Fail if any of these functions are missing
128AC_CHECK_FUNCS(socket strdup strlcpy strcasecmp strncasecmp snprintf vsnprintf)
129
130AC_CHECK_SIZEOF([long int])
131
132
133# Checks for header files.
134AC_HEADER_STDC
135AC_CHECK_HEADERS(pcap.h pcap-int.h pcap-bpf.h net/bpf.h sys/limits.h stddef.h inttypes.h limits.h net/ethernet.h sys/prctl.h)
136
137
138# OpenSolaris puts ncurses.h in /usr/include/ncurses rather than /usr/include,
139# so check for that
140AC_CHECK_HEADERS(ncurses.h,,[missing_ncurses=true])
141
142if test "x$missing_ncurses" = xtrue; then
143        if test -f "/usr/include/ncurses/ncurses.h"; then
144                AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Has nested ncurses header])
145        fi
146fi
147
148
149# Check for the presence of various networking headers and define appropriate
150# macros
151AC_CHECK_HEADERS(netinet/in.h)
152AC_CHECK_HEADERS(netpacket/packet.h,[
153        libtrace_netpacket_packet_h=true
154        AC_DEFINE(HAVE_NETPACKET_PACKET_H,1,[has net])
155])
156AC_CHECK_HEADER(net/if.h,
157        AC_DEFINE(HAVE_NET_IF_H,1,[has net/if.h header]),,[
158 #include <sys/types.h>
159 #include <sys/socket.h>
160])
161
162AC_CHECK_HEADER(netinet/ether.h,
163        AC_DEFINE(HAVE_NETINET_ETHER_H,1,[has netinet/ether.h header]),,[
164 #include <sys/types.h>
165 #include <sys/socket.h>
166 #include <netinet/in.h>
167 #include <net/if.h>
168])
169
170AC_CHECK_HEADER(netinet/if_ether.h,
171        AC_DEFINE(HAVE_NETINET_IF_ETHER_H,1,[has netinet/if_ether.h]),,[
172 #include <sys/types.h>
173 #include <sys/socket.h>
174 #include <netinet/in.h>
175 #include <net/if.h>
176])
177
178AC_CHECK_HEADER(net/if_arp.h,
179        AC_DEFINE(HAVE_NET_IF_ARP_H,1,[has net/if_arp.h]),,[
180 #include <sys/types.h>
181 #include <sys/socket.h>
182 #include <netinet/in.h>
183 #include <net/if.h>
184])
185
186# Check for sdl_len in sockaddr_dl - sockaddr_dl is used on BSD systems
187if test "$libtrace_netpacket_packet_h" != "true"; then
188        AC_CHECK_MEMBER([struct sockaddr_dl.sdl_len],
189                AC_DEFINE(HAVE_SDL_LEN,1,[Has sdl_len in sockaddr_dl]),,[
190 #include <sys/types.h>
191 #include <sys/socket.h>
192 #include <net/if_dl.h>
193                ])
194fi
195
196# Checking for the right bpf header to include
197AC_CHECK_HEADER(pcap-bpf.h)
198AC_CHECK_HEADER(net/bpf.h)
199
200# Checking for libgdc
201AC_CHECK_HEADER(gdc.h,AC_DEFINE(HAVE_LIBGDC,1,[has gdc.h]))
202
203# Check for libwandio (no longer bundled with libtrace)
204AC_CHECK_LIB(wandio,wandio_create,wandiofound=1,wandiofound=0)
205if test "$wandiofound" = 0; then
206        AC_MSG_ERROR(libwandio is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library. WANDIO can be obtained from http://research.wand.net.nz/software/libwandio.php)
207else
208        LIBTRACE_LIBS="$LIBTRACE_LIBS -lwandio"
209        TOOLS_LIBS="$TOOLS_LIBS -lwandio"
210        AC_DEFINE([HAVE_LIBWANDIO],1,[compile with libwandio support])
211fi
212
213AC_CHECK_LIB(crypto, EVP_EncryptInit_ex, cryptofound=1, cryptofound=0)
214
215# Check for libpcap
216AC_CHECK_LIB(pcap,pcap_next_ex,pcapfound=1,pcapfound=0)
217AC_CHECK_LIB(pcap,pcap_create,pcapcreate=1,pcapcreate=0)
218AC_CHECK_LIB(pcap,pcap_set_immediate_mode,pcapimmediate=1,pcapimmediate=0)
219AC_CHECK_DECLS([BIOCSETIF],,,[
220#include <sys/types.h>
221#include <sys/time.h>
222#include <sys/ioctl.h>
223#include <net/bpf.h>
224])
225
226AC_ARG_ENABLE(memory-debugging,
227                AS_HELP_STRING(--enable-memory-debugging, prints internal memory statistics),[
228                if test "$HAVE_TLS" = 1
229                then
230                    AC_DEFINE([ENABLE_MEM_STATS], 1, [print debug memory statistics])
231                fi
232],[])
233
234# Configure options for man pages
235AC_ARG_WITH(man,
236            AS_HELP_STRING(--with-man,install man pages by default),[
237             if test "$withval" = yes
238             then
239                     MANPAGES="docs/man/man3/[a-zA-Z]*.3"
240             else
241                     MANPAGES=""
242             fi
243])
244
245# Complain if we didn't find a suitable libpcap
246if test "$pcapfound" = 0; then
247        AC_MSG_ERROR(libpcap0.8 or greater is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library)
248else
249        TOOL_LIBS="$TOOL_LIBS -lpcap"
250        LIBTRACE_LIBS="$LIBTRACE_LIBS -lpcap"
251        AC_DEFINE([HAVE_LIBPCAP],1,[compile with libpcap support])
252        AC_DEFINE([HAVE_BPF_FILTER],1,[compile with bpf filter support])
253
254        LIBS="-lpcap"
255        AC_CHECK_FUNCS(pcap_inject pcap_sendpacket pcap_setnonblock)
256        LIBS=""
257
258fi
259
260if test "$pcapcreate" = 1; then
261        AC_DEFINE([HAVE_PCAP_CREATE],1,[compile with libpcap 1.0 support])
262fi
263
264if test "$pcapimmediate" = 1; then
265        AC_DEFINE([HAVE_PCAP_IMMEDIATE],1,[able to use pcap_set_immediate_mode])
266fi       
267
268# Configure options for use of DAG cards
269# Originally borrowed from libpcap, but extended quite a bit :)
270# More details on how this check works:
271#       http://wand.net.nz/trac/libtrace/wiki/DAGNotes
272
273AC_ARG_WITH(dag,
274            AS_HELP_STRING(--with-dag[=DIR],include DAG live capture support (located in directory DIR, if supplied)),
275[
276        if test "$withval" = no
277        then
278                want_dag=no
279        elif test "$withval" = yes
280        then
281                want_dag=yes
282                dag_root=/usr/local/dag
283        else
284                want_dag=yes
285                dag_root=$withval
286        fi
287],[
288        #
289        # Use DAG API if present, otherwise don't
290        #
291        want_dag=ifpresent
292        dag_root=/usr/local/dag
293])
294
295# DAG 3.0 actually puts header files and shared libraries into sensible
296# places now, so we should be able to do a simple CHECK_LIB to see if
297# they're there!
298
299# Addendum: It turns out DAG 2.5 does this too, so we'll match DAG2.5 in here
300# also. This isn't such a bad thing, the DAG2.5 API is essentially the same as
301# DAG 3.0 and libtrace will use the same format_dagXX source for both
302libtrace_dag=false
303libtrace_dag_version=none
304
305if test "$with_dag" != no; then
306        AC_CHECK_LIB(dag, dag_open, dag_found=1, dag_found=0)
307        if test "$dag_found" = 1; then
308                ADD_LIBS="$ADD_LIBS -ldag"
309                LIBTRACE_LIBS="$LIBTRACE_LIBS -ldag"
310                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
311                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
312                libtrace_dag=true
313               
314                AC_DEFINE(DAG_VERSION,25,[defines the DAG driver version])
315                libtrace_dag_version=25
316
317                AC_CHECK_HEADERS(dag_config_api.h,[csapi_found=1],,)
318                if test "$csapi_found" = 1; then
319                        LIBTRACE_LIBS="$LIBTRACE_LIBS -ldagconf"
320                fi
321        fi     
322fi
323
324# TODO: turn the test part of the next block into a function, so it can be
325# called multiple times for $dag_root, /root/dag, /usr/local/lib
326dag_drv_v="DAG not present"
327
328# Now check for 2.4 DAG drivers which don't install as cleanly!
329if test "$with_dag" != no -a "$libtrace_dag" = false; then
330        AC_MSG_CHECKING(whether we have DAG 2.4 API instead)
331
332        if test -r "$dag_root/lib"; then
333                dag_lib_dir="$dag_root/lib"
334        else
335                dag_lib_dir="$dag_root"
336        fi
337       
338        if test -r "$dag_root/include"; then
339                dag_tools_dir="$dag_root/tools"
340                dag_include_dir="$dag_root/include"
341        else
342                dag_tools_dir="$dag_root"
343                dag_include_dir="$dag_root"
344        fi
345
346        if test -r "$dag_include_dir/dagapi.h" -a -r "$dag_lib_dir/libdag.a";
347        then
348                ADD_INCLS="$ADD_INCLS -I $dag_include_dir"
349                ADD_LIBS="$ADD_LIBS -ldag"
350                ADD_LDFLAGS="$ADD_LDFLAGS -L$dag_lib_dir"
351                DAG_TOOLS_DIR=$dag_tools_dir
352                AC_SUBST([DAG_TOOLS_DIR])
353                libtrace_dag=true
354               
355                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
356                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
357                AC_DEFINE(DAG_VERSION, 24, [defines the DAG driver version])
358                libtrace_dag_version=24
359        else
360                if test "$want_dag" = yes; then
361                        AC_MSG_ERROR(DAG API not found under directory $dag_root
362; use --without-dag)
363                fi
364                libtrace_dag=false
365        fi
366        AC_MSG_RESULT($libtrace_dag)
367
368fi
369
370# Try to determine the DAG driver version
371#if test x"$libtrace_dag" = xtrue; then
372#       dag_drv_v="Unknown"
373#       files=`locate /usr/*dag*/VERSION`
374#       file_count=0
375#
376#       for i in $files; do
377#                if $file_count > 0; then
378#                        dag_drv_v="Indeterminate"
379#                        break
380#                fi
381#                dag_drv_v=`cat $i`
382#                file_count=$file_count+1
383#        done
384#fi
385#DAG_VERSION_NUM=$dag_drv_v
386
387# Check for DPDK
388AC_ARG_WITH(dpdk,
389            AS_HELP_STRING(--with-dpdk,include DPDK live capture support (Must set RTE_SDK/_TARGET environment variable)),
390[
391        if test "$withval" = no
392        then
393            want_dpdk=no
394        else
395            want_dpdk=ifpresent
396        fi
397],[
398        # Default to building without DPDK format
399        want_dpdk=no
400])
401
402libtrace_dpdk=false
403if test "$want_dpdk" != no; then
404    saved_ldflags="$LDFLAGS"
405    # Add to our libpath location
406    LDFLAGS="$LDFLAGS -L$RTE_SDK/$RTE_TARGET/lib/"
407    # Test that the library exists, we cannot be sure of what extra library flags need to be added
408    # this could change in the next version which would make the test fail
409    #AC_CHECK_LIB(intel_dpdk, rte_eal_init, dpdk_found=1, dpdk_found=0, -lpthread -lm -lrt)
410
411    # So instead simply check for existence
412    AC_CHECK_FILE("$RTE_SDK/$RTE_TARGET/lib/libintel_dpdk.a", dpdk_found=1, dpdk_found=0)
413    # Revert back
414    LDFLAGS="$saved_ldflags"
415    if test "$dpdk_found" = 1; then
416        # Save these now so that they can be re-exported later
417                AC_SUBST([RTE_TARGET])
418        AC_SUBST([RTE_SDK])
419        # Force dpdk library to be statically linked to allow compiler optimisations
420        LIBTRACE_LIBS="$LIBTRACE_LIBS -Wl,--whole-archive -Wl,-l:libintel_dpdk.a -Wl,--no-whole-archive -Wl,-lm"
421                AC_DEFINE(HAVE_DPDK,1,[conditional for building with DPDK live capture support])
422                libtrace_dpdk=true
423        fi
424fi
425
426# Check for PACKET_FANOUT (borrowed from Suricata)
427AC_CHECK_DECL([PACKET_FANOUT],
428        AC_DEFINE([HAVE_PACKET_FANOUT],[1],
429        [Recent packet fanout support is available]),
430        [],
431        [[#include <linux/if_packet.h>]])
432
433# If we use DPDK we might be able to use libnuma
434AC_CHECK_LIB(numa, numa_node_to_cpus, have_numa=1, have_numa=0)
435
436# Checks for various "optional" libraries
437AC_CHECK_LIB(pthread, pthread_create, have_pthread=1, have_pthread=0)
438
439AC_CHECK_LIB(pthread, pthread_setname_np, have_pthread_setname_np=1, have_pthread_setname_np=0)
440
441# Check for ncurses
442
443# These libraries have to be explicitly linked in OpenSolaris
444AC_SEARCH_LIBS(getservent, socket, have_socket=1, have_socket=0, -lnsl)
445LIBS=
446
447AC_SEARCH_LIBS(inet_ntop, nsl, have_nsl=1, have_nsl=0, -lsocket)
448LIBS=
449
450# Check to see if we have libdl - *BSD has built-in libdl
451AC_SEARCH_LIBS(dlopen,dl, dlfound=1,dlfound=0 )
452LIBS=
453
454# Check for clock_gettime
455AC_CHECK_LIB(rt, clock_gettime, have_clock_gettime=1, have_clock_gettime=0)
456LIBS=
457
458if test "$have_numa" = 1; then
459        LIBTRACE_LIBS="$LIBTRACE_LIBS -lnuma"
460        AC_DEFINE(HAVE_LIBNUMA, 1, [Set to 1 if libnuma is supported])
461        with_numa=yes
462else
463        AC_DEFINE(HAVE_LIBNUMA, 0, [Set to 1 if libnuma is supported])
464        with_numa=no
465fi
466
467if test "$dlfound" = 0; then
468        AC_MSG_ERROR("Unable to find dlopen. Please use LDFLAGS to specify the location of libdl and re-run configure")
469fi
470
471if test "$ac_cv_search_dlopen" != "none required"; then
472        LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_dlopen"
473        if test "$dpdk_found" = 1; then
474                LIBTRACE_LIBS="$LIBTRACE_LIBS -Wl,$ac_cv_search_dlopen"
475        fi
476fi
477
478if test "$have_pthread" = 1; then
479        AC_DEFINE(HAVE_LIBPTHREAD, 1, [Set to 1 if pthreads are supported])
480fi
481
482if test "$have_pthread_setname_np" = 1; then
483        AC_DEFINE(HAVE_PTHREAD_SETNAME_NP, 1, [Set to 1 if pthread_setname_np is found])
484fi
485
486if test "$cryptofound" = 1; then
487        AC_DEFINE(HAVE_LIBCRYPTO, 1, [Set to 1 if libcrypto is available])
488        TOOLS_LIBS="$TOOLS_LIBS -lcrypto"
489        have_crypto=yes
490else
491        have_crypto=no
492fi
493
494if test "$have_nsl" = 1; then
495        if test "$ac_cv_search_inet_ntop" != "none required"; then
496                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_inet_ntop"
497                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_inet_ntop"
498        fi
499fi
500
501if test "$have_socket" = 1; then
502        if test "$ac_cv_search_getservent" != "none required"; then
503                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_getservent"
504                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_getservent"
505        fi
506fi
507
508
509if test "$have_clock_gettime" = 1; then
510        LIBTRACE_LIBS="$LIBTRACE_LIBS -lrt"
511        AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Set to 1 if clock_gettime is supported])
512        with_clock_gettime=yes
513else
514        AC_DEFINE(HAVE_CLOCK_GETTIME, 0, [Set to 1 if clock_gettime is supported])
515        with_clock_gettime=no
516fi
517
518
519# Stupid AC_SEARCH_LIB appends stuff to LIBS even when I don't want it to, so
520# just set libs to null here to avoid linking against them by default
521LIBS=
522
523# For now, the user has to explicitly ask for the LLVM stuff, as it's a bit
524# rough around the edges :(
525AC_ARG_WITH([llvm],
526        [AC_HELP_STRING([--with-llvm],
527                [support Just In Time compiler])],
528        use_llvm="yes",
529        use_llvm="no")
530JIT=no
531
532# Search for LLVM and the libraries that it requires
533if (test "$use_llvm" != "no"); then
534        AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
535
536        # XXX Hard coding the path is REALLY bad.
537        # llvm-gcc is installed in a stupid place in Debian / Ubuntu. Hard luck
538        # if you've installed it somewhere custom.
539        # Hopefully in future we can replace this with clang, which may or may
540        # not be installed somewhere intelligent.
541        AC_PATH_PROG(LLVM_GCC, llvm-gcc, no, /usr/lib/llvm/llvm/gcc-4.2/bin)
542
543        AC_LANG_PUSH([C++])
544        AC_CHECK_HEADERS([boost/lexical_cast.hpp], boost="yes", boost="no")
545        AC_LANG_POP([C++])
546
547               
548        if test "$boost" = "no"; then
549                AC_MSG_NOTICE([Unabled to find boost libraries.  JIT support disabled.])
550                JIT=no
551        elif test "$LLVM_CONFIG" = "no" ; then
552                AC_MSG_NOTICE([Unable to find llvm-config.  JIT support disabled.])
553                JIT=no
554        elif test "$LLVM_GCC" = "no"; then
555                AC_MSG_NOTICE([Unable to find llvm-gcc.  JIT support disabled.])
556                JIT=no
557        else
558                LIBCXXFLAGS="`$LLVM_CONFIG --cxxflags` $CXXFLAGS"
559                LIBTRACE_LIBS="$LIBRACE_LIBS `$LLVM_CONFIG --libs all`";
560                LDFLAGS="`$LLVM_CONFIG --ldflags` $LDFLAGS";
561                JIT=yes
562                AC_DEFINE(HAVE_LLVM, 1, [Set to 1 if you have LLVM installed])
563        fi
564fi
565
566AC_ARG_WITH([ncurses],
567        AC_HELP_STRING([--with-ncurses], [build tracetop (requires ncurses)]))
568
569AS_IF([test "x$with_ncurses" != "xno"],
570        [AC_SEARCH_LIBS(mvprintw, ncurses, have_ncurses=yes, have_ncurses=no)
571         LIBS=
572        ], [have_ncurses=no])
573
574AS_IF([test "x$have_ncurses" = "xyes"], [
575        if test "$ac_cv_search_mvprintw" != "none required"; then
576                TOOLS_LIBS="$TOOLS_LIBS $ac_cv_search_mvprintw"
577        fi
578        AC_DEFINE(HAVE_NCURSES, 1, "Compiled with ncurses support")
579        with_ncurses=yes],
580
581       
582        [AS_IF([test "x$with_ncurses" = "xyes"],
583                [AC_MSG_ERROR([ncurses requested but not found])])
584        AC_DEFINE(HAVE_NCURSES, 0, "Compiled with ncurses support")
585        with_ncurses=no]
586)
587
588# Define automake conditionals for use in our Makefile.am files
589AM_CONDITIONAL([HAVE_BPF_CAPTURE], [test "$ac_cv_have_decl_BIOCSETIF" = yes ])
590AM_CONDITIONAL([HAVE_DAG], [test "$libtrace_dag" = true])
591AM_CONDITIONAL([HAVE_DPDK], [test "$libtrace_dpdk" = true])
592AM_CONDITIONAL([DAG2_4], [test "$libtrace_dag_version" = 24])
593AM_CONDITIONAL([DAG2_5], [test "$libtrace_dag_version" = 25])
594AM_CONDITIONAL([HAVE_NETPACKET_PACKET_H], [test "$libtrace_netpacket_packet_h" = true])
595AM_CONDITIONAL([HAVE_LIBGDC], [test "$ac_cv_header_gdc_h" = yes])
596AM_CONDITIONAL([HAVE_LLVM], [test "x$JIT" != "xno" ])
597AM_CONDITIONAL([HAVE_NCURSES], [test "x$with_ncurses" != "xno"])
598
599# Check for miscellaneous programs
600AC_CHECK_PROG([libtrace_doxygen], [doxygen], [true], [false])
601
602AM_CONDITIONAL(HAS_DOXYGEN, [test x"$libtrace_doxygen" = xtrue])
603
604# Set all our output variables
605AC_SUBST([LIBTRACE_LIBS])
606AC_SUBST([LIBPKTDUMP_LIBS])
607AC_SUBST([TOOLS_LIBS])
608#AC_SUBST([ADD_LIBS])
609AC_SUBST([ADD_LDFLAGS])
610AC_SUBST([ADD_INCLS])
611AC_SUBST([LTLIBOBJS])
612AC_SUBST([MANPAGES])
613AC_SUBST([PACKAGE_VERSION])
614AC_SUBST([LIBTRACE_MAJOR])
615AC_SUBST([LIBTRACE_MID])
616AC_SUBST([LIBTRACE_MINOR])
617AC_SUBST([DAG_VERSION_NUM])
618AC_SUBST([HAVE_BPF_CAPTURE])
619AC_SUBST([HAVE_LIBGDC])
620AC_SUBST([HAVE_LLVM])
621AC_SUBST([HAVE_NCURSES])
622AC_SUBST([LIBCFLAGS])
623AC_SUBST([LIBCXXFLAGS])
624
625
626# Finally, output our Makefiles
627AC_OUTPUT
628
629# Function for reporting whether an option was set or not
630reportopt() {
631        if test x"$2" = xtrue -o x"$2" = xyes; then
632                AC_MSG_NOTICE([$1: Yes])
633        else
634                AC_MSG_NOTICE([$1: No])
635        fi
636}
637
638
639# Report which configure options were set
640echo
641AC_MSG_NOTICE([Libtrace version $PACKAGE_VERSION])
642if test "$pcapcreate" = 1; then
643        AC_MSG_NOTICE([Compiled with PCAP support: >= 1.0])
644else
645        AC_MSG_NOTICE([Compiled with PCAP support: < 1.0])
646fi
647
648if test x"$libtrace_dag" = xtrue; then
649        if test "$libtrace_dag_version" = 24; then
650                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.4])
651        elif test "$libtrace_dag_version" = 30; then
652                AC_MSG_NOTICE([Compiled with DAG live capture support: 3.0])
653        else
654                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.5])
655        fi     
656else
657        AC_MSG_NOTICE([Compiled with DAG live capture support: No])
658fi
659
660if test x"$libtrace_dpdk" = xtrue; then
661        AC_MSG_NOTICE([Compiled with DPDK live capture support: Yes])
662        reportopt "Compiled with DPDK trace NUMA support" $with_numa
663        reportopt "Compiled with clock_gettime support" $with_clock_gettime
664elif test x"$want_dpdk" != "xno"; then
665#   We don't officially support DPDK so only report failure if the user
666#   explicitly asked for DPDK. That way, we can hopefully keep it hidden
667#   from most users for now...
668
669        AC_MSG_NOTICE([Compiled with DPDK live capture support: No])
670        AC_MSG_NOTICE([Note: Requires DPDK v1.5 or newer])
671fi
672reportopt "Compiled with LLVM BPF JIT support" $JIT
673reportopt "Building man pages/documentation" $libtrace_doxygen
674reportopt "Building tracetop (requires libncurses)" $with_ncurses
675reportopt "Building traceanon with CryptoPan (requires libcrypto)" $have_crypto
676
677# Report any errors relating to missing bison, flex, etc.
678echo
679ac_cv_errcount=0;
680if test -z "$YACC"; then
681        AC_MSG_WARN(bison or yacc not found. Please install bison before continuing)
682        ac_cv_errcount=$((ac_cv_errcount + 1))
683fi
684
685if test "x$LEX" != xflex -a "x$LEX" != xlex; then
686        AC_MSG_WARN(flex or lex not found. Please install flex before continuing)
687        ac_cv_errcount=$((ac_cv_errcount + 1))
688fi
689
690if test $ac_cv_errcount -gt 0; then
691        AC_MSG_ERROR(Critical packages are missing and compilation will fail. Please install the packages listed above and rerun ./configure)
692fi
693
Note: See TracBrowser for help on using the repository browser.