source: configure.in @ 9589941

4.0.1-hotfixescachetimestampsdevelopdpdk-ndagetsilivegetfragoffhelplibtrace4ndag_formatpfringrc-4.0.1rc-4.0.2rc-4.0.3rc-4.0.4ringdecrementfixringperformanceringtimestampfixes
Last change on this file since 9589941 was 9589941, checked in by Shane Alcock <salcock@…>, 10 years ago
  • Separated the libraries to link against into 3 separate categories: one for libtrace itself, one for libpacketdump and one for the tools. This means that each component only links against libraries that are actually used by something within it, reducing dependencies and keeping our Debian maintainer happy.
  • Also fixed a similar issue where libpacketdump did not explicitly link against libtrace
  • Property mode set to 100644
File size: 17.1 KB
Line 
1# Process this file with autoconf to produce a configure script.
2
3# Now you only need to update the version number in two places - below,
4# and in the README
5
6AC_INIT([libtrace],[3.0.10],[contact@wand.net.nz],[libtrace])
7
8LIBTRACE_MAJOR=3
9LIBTRACE_MID=0
10LIBTRACE_MINOR=10
11
12# OpenSolaris hides libraries like libncurses in /usr/gnu/lib, which is not
13# searched by default - add it to LDFLAGS so we at least have a chance of
14# finding it
15if test -d "/usr/gnu/lib"; then
16        LDFLAGS+=" -L/usr/gnu/lib"
17fi
18
19AC_CONFIG_MACRO_DIR([m4])
20AC_CONFIG_SRCDIR(lib/trace.c)
21AM_INIT_AUTOMAKE
22
23# Make sure we use the relatively silent automake output
24m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
25
26# Define our libtrace version number externally so we can use it in the source
27# as well, if needed.
28AC_DEFINE([LIBTRACE_MAJOR],${LIBTRACE_MAJOR},[libtrace major version])
29AC_DEFINE([LIBTRACE_MID],${LIBTRACE_MID},[libtrace mid version])
30AC_DEFINE([LIBTRACE_MINOR],${LIBTRACE_MINOR},[libtrace minor version])
31
32# These are all the files we want to be built for us by configure
33AC_CONFIG_FILES([Makefile lib/Makefile docs/Makefile libpacketdump/Makefile
34        tools/Makefile tools/traceanon/Makefile tools/tracepktdump/Makefile
35        tools/tracemerge/Makefile tools/tracereport/Makefile
36        tools/tracertstats/Makefile tools/tracesplit/Makefile
37        tools/tracestats/Makefile tools/tracetop/Makefile
38        tools/tracereplay/Makefile tools/tracediff/Makefile
39        examples/Makefile examples/skeleton/Makefile examples/rate/Makefile
40        examples/stats/Makefile examples/tutorial/Makefile
41        docs/libtrace.doxygen
42        lib/libtrace.h
43        ])
44
45
46# Function that checks if the C++ compiler actually works - there's a bit of
47# oversight in autoconf that will set the C++ compiler to g++ if no compiler
48# is found, even if g++ is not present! So we need an extra test to make sure
49# that the compiler works :(
50
51AC_DEFUN([rw_PROG_CXX_WORKS],
52[AC_REQUIRE([AC_PROG_CXX])dnl
53AC_CACHE_CHECK([whether the C++ compiler works],
54        [rw_cv_prog_cxx_works],
55        [AC_LANG_PUSH([C++])
56        AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
57                [rw_cv_prog_cxx_works=yes],
58                [rw_cv_prog_cxx_works=no])
59        AC_LANG_POP([C++])])
60])
61
62# Put all our automake definitions in config.h
63AM_CONFIG_HEADER([config.h])
64
65# Checks for C and C++ compilers
66AC_PROG_CC
67AC_PROG_CXX
68rw_PROG_CXX_WORKS
69
70if test "$rw_cv_prog_cxx_works" = "no"; then
71        AC_MSG_ERROR("Failed to find working C++ compiler")
72fi
73
74# Checking for 'install'
75AC_PROG_INSTALL
76
77# Checking for bison and flex
78AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc)
79AM_PROG_LEX
80
81# All our source files for function replacements are in lib/
82AC_CONFIG_LIBOBJ_DIR(lib)
83
84# Check for various "replacement" functions
85AC_FUNC_MALLOC
86AC_FUNC_REALLOC
87
88# *BSD doesn't have strndup. Currently provide our own.
89AC_REPLACE_FUNCS(strndup)
90
91
92# Checks for typedefs, structures, and compiler characteristics.
93AC_C_CONST
94AC_C_INLINE
95AC_C_BIGENDIAN
96AC_TYPE_SIZE_T
97AC_HEADER_TIME
98AC_SYS_LARGEFILE
99
100LIBPKTDUMP_LIBS="-ltrace "
101LIBTRACE_LIBS=""
102TOOLS_LIBS=""
103
104# Set our C compiler flags based on the gcc version
105if test "$GCC" = "yes"; then
106       
107        gcc_version=`gcc -dumpversion`
108
109        # This is probably not the most reliable way to test whether our
110        # compiler supports visibility, but it's better than nothing
111        #
112        # According to the gcc wiki - http://gcc.gnu.org/wiki/Visibility -
113        # visibility is supported in gcc 4.0 or later, so we just need to
114        # check the major version number
115
116        major=${gcc_version%\.*\.*}
117
118        if test "$major" -lt 4; then
119                vis=no
120        else
121                vis=yes
122        fi
123       
124        CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
125        CXXFLAGS="$CXXFLAGS -Wall"
126        LIBCFLAGS="$CFLAGS"
127        LIBCFLAGS="$LIBCFLAGS -DLT_BUILDING_DLL=1"
128        LIBCXXFLAGS="$CXXFLAGS"
129        LIBCXXFLAGS="$CXXFLAGS -DLT_BUILDING_DLL=1"
130       
131        if test "$vis" = "yes"; then
132                LIBCFLAGS="$LIBCFLAGS -Wextra -fvisibility=hidden"
133                LIBCXXFLAGS="$CXXFLAGS -Wextra -fvisibility=hidden"
134        fi
135fi
136
137# Check for libtool
138AC_PROG_LIBTOOL
139
140# Checks for library functions.
141AC_PROG_GCC_TRADITIONAL
142
143# Fail if any of these functions are missing
144AC_CHECK_FUNCS(socket strdup strlcpy strcasecmp strncasecmp snprintf vsnprintf)
145
146AC_CHECK_SIZEOF([long int])
147
148
149# Checks for header files.
150AC_HEADER_STDC
151AC_CHECK_HEADERS(pcap.h pcap-int.h pcap-bpf.h net/bpf.h sys/limits.h stddef.h inttypes.h limits.h net/ethernet.h sys/prctl.h)
152
153
154# OpenSolaris puts ncurses.h in /usr/include/ncurses rather than /usr/include,
155# so check for that
156AC_CHECK_HEADERS(ncurses.h,,[missing_ncurses=true])
157
158if test "x$missing_ncurses" = xtrue; then
159        if test -f "/usr/include/ncurses/ncurses.h"; then
160                AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Has nested ncurses header])
161        fi
162fi
163
164
165# Check for the presence of various networking headers and define appropriate
166# macros
167AC_CHECK_HEADERS(netinet/in.h)
168AC_CHECK_HEADERS(netpacket/packet.h,[
169        libtrace_netpacket_packet_h=true
170        AC_DEFINE(HAVE_NETPACKET_PACKET_H,1,[has net])
171])
172AC_CHECK_HEADER(net/if.h,
173        AC_DEFINE(HAVE_NET_IF_H,1,[has net/if.h header]),,[
174 #include <sys/types.h>
175 #include <sys/socket.h>
176])
177
178AC_CHECK_HEADER(netinet/ether.h,
179        AC_DEFINE(HAVE_NETINET_ETHER_H,1,[has netinet/ether.h header]),,[
180 #include <sys/types.h>
181 #include <sys/socket.h>
182 #include <netinet/in.h>
183 #include <net/if.h>
184])
185
186AC_CHECK_HEADER(netinet/if_ether.h,
187        AC_DEFINE(HAVE_NETINET_IF_ETHER_H,1,[has netinet/if_ether.h]),,[
188 #include <sys/types.h>
189 #include <sys/socket.h>
190 #include <netinet/in.h>
191 #include <net/if.h>
192])
193
194AC_CHECK_HEADER(net/if_arp.h,
195        AC_DEFINE(HAVE_NET_IF_ARP_H,1,[has net/if_arp.h]),,[
196 #include <sys/types.h>
197 #include <sys/socket.h>
198 #include <netinet/in.h>
199 #include <net/if.h>
200])
201
202# Check for sdl_len in sockaddr_dl - sockaddr_dl is used on BSD systems
203if test "$libtrace_netpacket_packet_h" != "true"; then
204        AC_CHECK_MEMBER([struct sockaddr_dl.sdl_len],
205                AC_DEFINE(HAVE_SDL_LEN,1,[Has sdl_len in sockaddr_dl]),,[
206 #include <sys/types.h>
207 #include <sys/socket.h>
208 #include <net/if_dl.h>
209                ])
210fi
211
212# Checking for the right bpf header to include
213AC_CHECK_HEADER(pcap-bpf.h)
214AC_CHECK_HEADER(net/bpf.h)
215
216# Checking for libgdc
217AC_CHECK_HEADER(gdc.h,AC_DEFINE(HAVE_LIBGDC,1,[has gdc.h]))
218
219# Check for libpcap
220AC_CHECK_LIB(pcap,pcap_next_ex,pcapfound=1,pcapfound=0)
221AC_CHECK_FUNCS(pcap_inject pcap_sendpacket pcap_setnonblock)
222AC_CHECK_DECLS([BIOCSETIF],,,[
223#include <sys/types.h>
224#include <sys/time.h>
225#include <sys/ioctl.h>
226#include <net/bpf.h>
227])
228
229# Configure options for man pages
230AC_ARG_WITH(man,
231            AS_HELP_STRING(--with-man,install man pages by default),[
232             if test "$withval" = yes
233             then
234                     MANPAGES="docs/man/man3/[a-zA-Z]*.3"
235             else
236                     MANPAGES=""
237             fi
238])
239
240# Complain if we didn't find a suitable libpcap
241if test "$pcapfound" = 0; then
242        AC_MSG_ERROR(libpcap0.8 or greater is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library)
243else
244        TOOL_LIBS="$TOOL_LIBS -lpcap"
245        LIBTRACE_LIBS="$LIBTRACE_LIBS -lpcap"
246        AC_DEFINE([HAVE_LIBPCAP],1,[compile with libpcap support])
247        AC_DEFINE([HAVE_BPF_FILTER],1,[compile with bpf filter support])
248fi
249
250# Configure options for use of DAG cards
251# Originally borrowed from libpcap, but extended quite a bit :)
252# More details on how this check works:
253#       http://wand.net.nz/trac/libtrace/wiki/DAGNotes
254
255AC_ARG_WITH(dag,
256            AS_HELP_STRING(--with-dag[=DIR],include DAG live capture support (located in directory DIR, if supplied)),
257[
258        if test "$withval" = no
259        then
260                want_dag=no
261        elif test "$withval" = yes
262        then
263                want_dag=yes
264                dag_root=/usr/local/dag
265        else
266                want_dag=yes
267                dag_root=$withval
268        fi
269],[
270        #
271        # Use DAG API if present, otherwise don't
272        #
273        want_dag=ifpresent
274        dag_root=/usr/local/dag
275])
276
277# DAG 3.0 actually puts header files and shared libraries into sensible
278# places now, so we should be able to do a simple CHECK_LIB to see if
279# they're there!
280
281# Addendum: It turns out DAG 2.5 does this too, so we'll match DAG2.5 in here
282# also. This isn't such a bad thing, the DAG2.5 API is essentially the same as
283# DAG 3.0 and libtrace will use the same format_dagXX source for both
284libtrace_dag=false
285libtrace_dag_version=none
286
287if test "$with_dag" != no; then
288        AC_CHECK_LIB(dag, dag_open, dag_found=1, dag_found=0)
289        if test "$dag_found" = 1; then
290                ADD_LIBS="$ADD_LIBS -ldag"
291                LIBTRACE_LIBS="$LIBTRACE_LIBS -ldag"
292                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
293                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
294                libtrace_dag=true
295               
296                AC_DEFINE(DAG_VERSION,25,[defines the DAG driver version])
297                libtrace_dag_version=25
298        fi
299fi
300
301# TODO: turn the test part of the next block into a function, so it can be
302# called multiple times for $dag_root, /root/dag, /usr/local/lib
303dag_drv_v="DAG not present"
304
305# Now check for 2.4 DAG drivers which don't install as cleanly!
306if test "$with_dag" != no -a "$libtrace_dag" = false; then
307        AC_MSG_CHECKING(whether we have DAG 2.4 API instead)
308
309        if test -r "$dag_root/lib"; then
310                dag_lib_dir="$dag_root/lib"
311        else
312                dag_lib_dir="$dag_root"
313        fi
314       
315        if test -r "$dag_root/include"; then
316                dag_tools_dir="$dag_root/tools"
317                dag_include_dir="$dag_root/include"
318        else
319                dag_tools_dir="$dag_root"
320                dag_include_dir="$dag_root"
321        fi
322
323        if test -r "$dag_include_dir/dagapi.h" -a -r "$dag_lib_dir/libdag.a";
324        then
325                ADD_INCLS="$ADD_INCLS -I $dag_include_dir"
326                ADD_LIBS="$ADD_LIBS -ldag"
327                ADD_LDFLAGS="$ADD_LDFLAGS -L$dag_lib_dir"
328                DAG_TOOLS_DIR=$dag_tools_dir
329                AC_SUBST([DAG_TOOLS_DIR])
330                libtrace_dag=true
331               
332                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
333                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
334                AC_DEFINE(DAG_VERSION, 24, [defines the DAG driver version])
335                libtrace_dag_version=24
336        else
337                if test "$want_dag" = yes; then
338                        AC_MSG_ERROR(DAG API not found under directory $dag_root
339; use --without-dag)
340                fi
341                libtrace_dag=false
342        fi
343        AC_MSG_RESULT($libtrace_dag)
344
345fi
346
347# Try to determine the DAG driver version
348#if test x"$libtrace_dag" = xtrue; then
349#       dag_drv_v="Unknown"
350#       files=`locate /usr/*dag*/VERSION`
351#       file_count=0
352#
353#       for i in $files; do
354#                if $file_count > 0; then
355#                        dag_drv_v="Indeterminate"
356#                        break
357#                fi
358#                dag_drv_v=`cat $i`
359#                file_count=$file_count+1
360#        done
361#fi
362#DAG_VERSION_NUM=$dag_drv_v
363
364have_ncurses=yes
365
366# Checks for various "optional" libraries
367AC_CHECK_LIB(z, deflate, have_zlib=1, have_zlib=0)
368AC_CHECK_LIB(bz2, BZ2_bzDecompressInit, have_bzip=1, have_bzip=0)
369AC_CHECK_LIB(lzo2, lzo1x_1_compress, have_lzo=1, have_lzo=0)
370AC_CHECK_LIB(pthread, pthread_create, have_pthread=1, have_pthread=0)
371
372# Check for ncurses
373AC_SEARCH_LIBS(mvprintw, ncurses, have_ncurses=yes, have_ncurses=no)
374LIBS=
375
376# These libraries have to be explicitly linked in OpenSolaris
377AC_SEARCH_LIBS(getservent, socket, have_socket=1, have_socket=0, -lnsl)         
378LIBS=
379
380AC_SEARCH_LIBS(inet_ntop, nsl, have_nsl=1, have_nsl=0, -lsocket)
381LIBS=
382
383# Check to see if we have libdl - *BSD has built-in libdl
384AC_SEARCH_LIBS(dlopen,dl, dlfound=1,dlfound=0 )
385LIBS=
386
387if test "$dlfound" = 0; then
388        AC_MSG_ERROR("Unable to find dlopen. Please use LDFLAGS to specify the location of libdl and re-run configure")
389fi
390
391if test "$ac_cv_search_dlopen" != "none required"; then
392        LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_dlopen"
393fi
394
395
396if test "$have_zlib" = 1; then
397        LIBTRACE_LIBS="$LIBTRACE_LIBS -lz"
398        AC_DEFINE(HAVE_LIBZ, 1, [Set to 1 if zlib is supported])
399fi
400
401if test "$have_bzip" = 1; then
402        LIBTRACE_LIBS="$LIBTRACE_LIBS -lbz2"
403        AC_DEFINE(HAVE_LIBBZ2, 1, [Set to 1 if bzip2 is supported])
404fi
405
406if test "$have_lzo" = 1; then
407        LIBTRACE_LIBS="$LIBTRACE_LIBS -llzo2"
408        AC_DEFINE(HAVE_LIBLZO2, 1, [Set to 1 if lzo2 is supported])
409fi
410
411if test "$have_pthread" = 1; then
412        LIBTRACE_LIBS="$LIBTRACE_LIBS -lpthread"
413        AC_DEFINE(HAVE_LIBPTHREAD, 1, [Set to 1 if pthreads are supported])
414fi
415
416if test "$have_ncurses" = "yes"; then
417        if test "$ac_cv_search_mvprintw" != "none required"; then
418                TOOLS_LIBS="$TOOLS_LIBS $ac_cv_search_mvprintw"
419        fi
420fi
421
422if test "$have_nsl" = 1; then
423        if test "$ac_cv_search_inet_ntop" != "none required"; then
424                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_inet_ntop"
425                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_inet_ntop"
426        fi
427fi
428
429if test "$have_socket" = 1; then
430        if test "$ac_cv_search_getservent" != "none required"; then
431                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_getservent"
432                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_getservent"
433        fi
434fi
435
436
437# Stupid AC_SEARCH_LIB appends stuff to LIBS even when I don't want it to, so
438# just set libs to null here to avoid linking against them by default
439LIBS=
440
441
442# For now, the user has to explicitly ask for the LLVM stuff, as it's a bit
443# rough around the edges :(
444AC_ARG_WITH([llvm],
445        [AC_HELP_STRING([--with-llvm],
446                [support Just In Time compiler])],
447        use_llvm="yes",
448        use_llvm="no")
449JIT=no
450
451# Search for LLVM and the libraries that it requires
452if (test "$use_llvm" != "no"); then
453        AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
454
455        # XXX Hard coding the path is REALLY bad.
456        # llvm-gcc is installed in a stupid place in Debian / Ubuntu. Hard luck
457        # if you've installed it somewhere custom.
458        # Hopefully in future we can replace this with clang, which may or may
459        # not be installed somewhere intelligent.
460        AC_PATH_PROG(LLVM_GCC, llvm-gcc, no, /usr/lib/llvm/llvm/gcc-4.2/bin)
461
462        AC_LANG_PUSH([C++])
463        AC_CHECK_HEADERS([boost/lexical_cast.hpp], boost="yes", boost="no")
464        AC_LANG_POP([C++])
465
466               
467        if test "$boost" = "no"; then
468                AC_MSG_NOTICE([Unabled to find boost libraries.  JIT support disabled.])
469                JIT=no
470        elif test "$LLVM_CONFIG" = "no" ; then
471                AC_MSG_NOTICE([Unable to find llvm-config.  JIT support disabled.])
472                JIT=no
473        elif test "$LLVM_GCC" = "no"; then
474                AC_MSG_NOTICE([Unable to find llvm-gcc.  JIT support disabled.])
475                JIT=no
476        else
477                LIBCXXFLAGS="`$LLVM_CONFIG --cxxflags` $CXXFLAGS"
478                LIBTRACE_LIBS="$LIBRACE_LIBS `$LLVM_CONFIG --libs all`";
479                LDFLAGS="`$LLVM_CONFIG --ldflags` $LDFLAGS";
480                JIT=yes
481                AC_DEFINE(HAVE_LLVM, 1, [Set to 1 if you have LLVM installed])
482        fi
483fi
484
485
486# Define automake conditionals for use in our Makefile.am files
487AM_CONDITIONAL([HAVE_BPF_CAPTURE], [test "$ac_cv_have_decl_BIOCSETIF" = yes ])
488AM_CONDITIONAL([HAVE_DAG], [test "$libtrace_dag" = true])
489AM_CONDITIONAL([DAG2_4], [test "$libtrace_dag_version" = 24])
490AM_CONDITIONAL([DAG2_5], [test "$libtrace_dag_version" = 25])
491AM_CONDITIONAL([HAVE_ZLIB], [test "$have_zlib" = 1])
492AM_CONDITIONAL([HAVE_BZLIB], [test "$have_bzip" = 1])
493AM_CONDITIONAL([HAVE_LZO], [test "$have_lzo" = 1])
494AM_CONDITIONAL([HAVE_NETPACKET_PACKET_H], [test "$libtrace_netpacket_packet_h" = true])
495AM_CONDITIONAL([HAVE_LIBGDC], [test "$ac_cv_header_gdc_h" = yes])
496AM_CONDITIONAL([HAVE_LLVM], [test "x$JIT" != "xno" ])
497AM_CONDITIONAL([HAVE_NCURSES], [test "$xhave_ncurses" = "xyes"])
498
499# Check for miscellaneous programs
500AC_CHECK_PROG([libtrace_doxygen], [doxygen], [true], [false])
501
502AM_CONDITIONAL(HAS_DOXYGEN, [test x"$libtrace_doxygen" = xtrue])
503
504# Set all our output variables
505AC_SUBST([LIBTRACE_LIBS])
506AC_SUBST([LIBPKTDUMP_LIBS])
507AC_SUBST([TOOLS_LIBS])
508#AC_SUBST([ADD_LIBS])
509AC_SUBST([ADD_LDFLAGS])
510AC_SUBST([ADD_INCLS])
511AC_SUBST([LTLIBOBJS])
512AC_SUBST([MANPAGES])
513AC_SUBST([PACKAGE_VERSION])
514AC_SUBST([LIBTRACE_MAJOR])
515AC_SUBST([LIBTRACE_MID])
516AC_SUBST([LIBTRACE_MINOR])
517AC_SUBST([DAG_VERSION_NUM])
518AC_SUBST([HAVE_BPF_CAPTURE])
519AC_SUBST([HAVE_LIBGDC])
520AC_SUBST([HAVE_LLVM])
521AC_SUBST([HAVE_NCURSES])
522AC_SUBST([LIBCFLAGS])
523AC_SUBST([LIBCXXFLAGS])
524
525
526# Finally, output our Makefiles
527AC_OUTPUT
528
529# Function for reporting whether an option was set or not
530reportopt() {
531        if test x"$2" = xtrue -o x"$2" = xyes; then
532                AC_MSG_NOTICE([$1: Yes])
533        else
534                AC_MSG_NOTICE([$1: No])
535        fi
536}
537
538
539# Report which configure options were set
540echo
541AC_MSG_NOTICE([Libtrace version $PACKAGE_VERSION])
542reportopt "Compiled with PCAP 0.8 support" $ac_cv_lib_pcap_pcap_next_ex
543reportopt "Compiled with compressed trace (zlib) support" $ac_cv_lib_z_deflate
544reportopt "Compiled with compressed trace (bz2) support" $ac_cv_lib_bz2_BZ2_bzDecompressInit
545reportopt "Compiled with compressed trace (lzo write only) support" $ac_cv_lib_lzo2_lzo1x_1_compress
546if test x"$libtrace_dag" = xtrue; then
547        if test "$libtrace_dag_version" = 24; then
548                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.4])
549        elif test "$libtrace_dag_version" = 30; then
550                AC_MSG_NOTICE([Compiled with DAG live capture support: 3.0])
551        else
552                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.5])
553        fi     
554else
555        AC_MSG_NOTICE([Compiled with DAG live capture support: No])
556fi
557reportopt "Compiled with LLVM BPF JIT support" $JIT
558reportopt "Building man pages/documentation" $libtrace_doxygen
559reportopt "Building tracetop (requires libncurses)" $have_ncurses
560
561# Report any errors relating to missing bison, flex, etc.
562echo
563ac_cv_errcount=0;
564if test -z "$YACC"; then
565        AC_MSG_WARN(bison or yacc not found. Please install bison before continuing)
566        ac_cv_errcount=$((ac_cv_errcount + 1))
567fi
568
569if test -z "$LEXLIB"; then
570        AC_MSG_WARN(flex or lex not found. Please install flex before continuing)
571        ac_cv_errcount=$((ac_cv_errcount + 1))
572fi
573
574if test $ac_cv_errcount -gt 0; then
575        AC_MSG_ERROR(Critical packages are missing and compilation will fail. Please install the packages listed above and rerun ./configure)
576fi
577
Note: See TracBrowser for help on using the repository browser.