source: configure.in @ 60f3c4c

4.0.1-hotfixescachetimestampsdevelopdpdk-ndagetsilivegetfragoffhelplibtrace4ndag_formatpfringrc-4.0.1rc-4.0.2rc-4.0.3rc-4.0.4ringdecrementfixringperformanceringtimestampfixes
Last change on this file since 60f3c4c was 60f3c4c, checked in by Shane Alcock <salcock@…>, 9 years ago
  • Shifted wandio into a separate library, seeing as we're going to be exporting the API now
  • Property mode set to 100644
File size: 19.2 KB
Line 
1# Process this file with autoconf to produce a configure script.
2
3# Now you only need to update the version number in two places - below,
4# and in the README
5
6AC_INIT([libtrace],[3.0.14],[contact@wand.net.nz],[libtrace])
7
8LIBTRACE_MAJOR=3
9LIBTRACE_MID=0
10LIBTRACE_MINOR=14
11
12# OpenSolaris hides libraries like libncurses in /usr/gnu/lib, which is not
13# searched by default - add it to LDFLAGS so we at least have a chance of
14# finding it
15if test -d "/usr/gnu/lib"; then
16        LDFLAGS+=" -L/usr/gnu/lib"
17fi
18
19AC_CONFIG_MACRO_DIR([m4])
20AC_CONFIG_SRCDIR(lib/trace.c)
21AM_INIT_AUTOMAKE
22
23# Make sure we use the relatively silent automake output
24m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
25
26# Define our libtrace version number externally so we can use it in the source
27# as well, if needed.
28AC_DEFINE([LIBTRACE_MAJOR],${LIBTRACE_MAJOR},[libtrace major version])
29AC_DEFINE([LIBTRACE_MID],${LIBTRACE_MID},[libtrace mid version])
30AC_DEFINE([LIBTRACE_MINOR],${LIBTRACE_MINOR},[libtrace minor version])
31
32# These are all the files we want to be built for us by configure
33AC_CONFIG_FILES([Makefile lib/Makefile docs/Makefile libpacketdump/Makefile
34        tools/Makefile tools/traceanon/Makefile tools/tracepktdump/Makefile
35        tools/tracemerge/Makefile tools/tracereport/Makefile
36        tools/tracertstats/Makefile tools/tracesplit/Makefile
37        tools/tracestats/Makefile tools/tracetop/Makefile
38        tools/tracereplay/Makefile tools/tracediff/Makefile
39        tools/traceends/Makefile
40        examples/Makefile examples/skeleton/Makefile examples/rate/Makefile
41        examples/stats/Makefile examples/tutorial/Makefile
42        docs/libtrace.doxygen
43        lib/libtrace.h libwandio/Makefile
44        ])
45
46
47# Function that checks if the C++ compiler actually works - there's a bit of
48# oversight in autoconf that will set the C++ compiler to g++ if no compiler
49# is found, even if g++ is not present! So we need an extra test to make sure
50# that the compiler works :(
51
52AC_DEFUN([rw_PROG_CXX_WORKS],
53[AC_REQUIRE([AC_PROG_CXX])dnl
54AC_CACHE_CHECK([whether the C++ compiler works],
55        [rw_cv_prog_cxx_works],
56        [AC_LANG_PUSH([C++])
57        AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
58                [rw_cv_prog_cxx_works=yes],
59                [rw_cv_prog_cxx_works=no])
60        AC_LANG_POP([C++])])
61])
62
63# Put all our automake definitions in config.h
64AM_CONFIG_HEADER([config.h])
65
66# Checks for C and C++ compilers
67AC_PROG_CC
68AC_PROG_CXX
69rw_PROG_CXX_WORKS
70
71if test "$rw_cv_prog_cxx_works" = "no"; then
72        AC_MSG_ERROR("Failed to find working C++ compiler")
73fi
74
75# Checking for 'install'
76AC_PROG_INSTALL
77
78# Checking for bison and flex
79AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc)
80AM_PROG_LEX
81
82# All our source files for function replacements are in lib/
83AC_CONFIG_LIBOBJ_DIR(lib)
84
85# Check for various "replacement" functions
86AC_FUNC_MALLOC
87AC_FUNC_REALLOC
88
89# *BSD doesn't have strndup. Currently provide our own.
90AC_REPLACE_FUNCS(strndup)
91
92
93# Checks for typedefs, structures, and compiler characteristics.
94AC_C_CONST
95AC_C_INLINE
96AC_C_BIGENDIAN
97AC_TYPE_SIZE_T
98AC_HEADER_TIME
99AC_SYS_LARGEFILE
100
101LIBPKTDUMP_LIBS="-ltrace "
102ADD_LDFLAGS="$ADD_LDFLAGS -L\$(abs_top_srcdir)/libwandio -L\$(abs_top_srcdir)/lib"
103LIBTRACE_LIBS="-lwandio"
104TOOLS_LIBS=""
105LIBWANDIO_LIBS=""
106
107# Set our C compiler flags based on the gcc version
108if test "$GCC" = "yes"; then
109       
110        gcc_version=`gcc -dumpversion`
111
112        # This is probably not the most reliable way to test whether our
113        # compiler supports visibility, but it's better than nothing
114        #
115        # According to the gcc wiki - http://gcc.gnu.org/wiki/Visibility -
116        # visibility is supported in gcc 4.0 or later, so we just need to
117        # check the major version number
118
119        major=${gcc_version%\.*\.*}
120
121        if test "$major" -lt 4; then
122                vis=no
123        else
124                vis=yes
125        fi
126       
127        CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
128        CXXFLAGS="$CXXFLAGS -Wall"
129        LIBCFLAGS="$CFLAGS"
130        LIBCFLAGS="$LIBCFLAGS -DLT_BUILDING_DLL=1"
131        LIBCXXFLAGS="$CXXFLAGS"
132        LIBCXXFLAGS="$CXXFLAGS -DLT_BUILDING_DLL=1"
133       
134        if test "$vis" = "yes"; then
135                LIBCFLAGS="$LIBCFLAGS -Wextra -fvisibility=hidden"
136                LIBCXXFLAGS="$CXXFLAGS -Wextra -fvisibility=hidden"
137        fi
138fi
139
140# Check for libtool
141AC_PROG_LIBTOOL
142
143# Checks for library functions.
144AC_PROG_GCC_TRADITIONAL
145
146# Fail if any of these functions are missing
147AC_CHECK_FUNCS(socket strdup strlcpy strcasecmp strncasecmp snprintf vsnprintf)
148
149AC_CHECK_SIZEOF([long int])
150
151
152# Checks for header files.
153AC_HEADER_STDC
154AC_CHECK_HEADERS(pcap.h pcap-int.h pcap-bpf.h net/bpf.h sys/limits.h stddef.h inttypes.h limits.h net/ethernet.h sys/prctl.h)
155
156
157# OpenSolaris puts ncurses.h in /usr/include/ncurses rather than /usr/include,
158# so check for that
159AC_CHECK_HEADERS(ncurses.h,,[missing_ncurses=true])
160
161if test "x$missing_ncurses" = xtrue; then
162        if test -f "/usr/include/ncurses/ncurses.h"; then
163                AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Has nested ncurses header])
164        fi
165fi
166
167
168# Check for the presence of various networking headers and define appropriate
169# macros
170AC_CHECK_HEADERS(netinet/in.h)
171AC_CHECK_HEADERS(netpacket/packet.h,[
172        libtrace_netpacket_packet_h=true
173        AC_DEFINE(HAVE_NETPACKET_PACKET_H,1,[has net])
174])
175AC_CHECK_HEADER(net/if.h,
176        AC_DEFINE(HAVE_NET_IF_H,1,[has net/if.h header]),,[
177 #include <sys/types.h>
178 #include <sys/socket.h>
179])
180
181AC_CHECK_HEADER(netinet/ether.h,
182        AC_DEFINE(HAVE_NETINET_ETHER_H,1,[has netinet/ether.h header]),,[
183 #include <sys/types.h>
184 #include <sys/socket.h>
185 #include <netinet/in.h>
186 #include <net/if.h>
187])
188
189AC_CHECK_HEADER(netinet/if_ether.h,
190        AC_DEFINE(HAVE_NETINET_IF_ETHER_H,1,[has netinet/if_ether.h]),,[
191 #include <sys/types.h>
192 #include <sys/socket.h>
193 #include <netinet/in.h>
194 #include <net/if.h>
195])
196
197AC_CHECK_HEADER(net/if_arp.h,
198        AC_DEFINE(HAVE_NET_IF_ARP_H,1,[has net/if_arp.h]),,[
199 #include <sys/types.h>
200 #include <sys/socket.h>
201 #include <netinet/in.h>
202 #include <net/if.h>
203])
204
205# Check for sdl_len in sockaddr_dl - sockaddr_dl is used on BSD systems
206if test "$libtrace_netpacket_packet_h" != "true"; then
207        AC_CHECK_MEMBER([struct sockaddr_dl.sdl_len],
208                AC_DEFINE(HAVE_SDL_LEN,1,[Has sdl_len in sockaddr_dl]),,[
209 #include <sys/types.h>
210 #include <sys/socket.h>
211 #include <net/if_dl.h>
212                ])
213fi
214
215# Checking for the right bpf header to include
216AC_CHECK_HEADER(pcap-bpf.h)
217AC_CHECK_HEADER(net/bpf.h)
218
219# Checking for libgdc
220AC_CHECK_HEADER(gdc.h,AC_DEFINE(HAVE_LIBGDC,1,[has gdc.h]))
221
222# Check for libpcap
223AC_CHECK_LIB(pcap,pcap_next_ex,pcapfound=1,pcapfound=0)
224AC_CHECK_LIB(pcap,pcap_create,pcapcreate=1,pcapcreate=0)
225AC_CHECK_FUNCS(pcap_inject pcap_sendpacket pcap_setnonblock)
226AC_CHECK_DECLS([BIOCSETIF],,,[
227#include <sys/types.h>
228#include <sys/time.h>
229#include <sys/ioctl.h>
230#include <net/bpf.h>
231])
232
233# Configure options for man pages
234AC_ARG_WITH(man,
235            AS_HELP_STRING(--with-man,install man pages by default),[
236             if test "$withval" = yes
237             then
238                     MANPAGES="docs/man/man3/[a-zA-Z]*.3"
239             else
240                     MANPAGES=""
241             fi
242])
243
244# Complain if we didn't find a suitable libpcap
245if test "$pcapfound" = 0; then
246        AC_MSG_ERROR(libpcap0.8 or greater is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library)
247else
248        TOOL_LIBS="$TOOL_LIBS -lpcap"
249        LIBTRACE_LIBS="$LIBTRACE_LIBS -lpcap"
250        AC_DEFINE([HAVE_LIBPCAP],1,[compile with libpcap support])
251        AC_DEFINE([HAVE_BPF_FILTER],1,[compile with bpf filter support])
252fi
253
254if test "$pcapcreate" = 1; then
255        AC_DEFINE([HAVE_PCAP_CREATE],1,[compile with libpcap 1.0 support])
256fi
257
258# Configure options for use of DAG cards
259# Originally borrowed from libpcap, but extended quite a bit :)
260# More details on how this check works:
261#       http://wand.net.nz/trac/libtrace/wiki/DAGNotes
262
263AC_ARG_WITH(dag,
264            AS_HELP_STRING(--with-dag[=DIR],include DAG live capture support (located in directory DIR, if supplied)),
265[
266        if test "$withval" = no
267        then
268                want_dag=no
269        elif test "$withval" = yes
270        then
271                want_dag=yes
272                dag_root=/usr/local/dag
273        else
274                want_dag=yes
275                dag_root=$withval
276        fi
277],[
278        #
279        # Use DAG API if present, otherwise don't
280        #
281        want_dag=ifpresent
282        dag_root=/usr/local/dag
283])
284
285# DAG 3.0 actually puts header files and shared libraries into sensible
286# places now, so we should be able to do a simple CHECK_LIB to see if
287# they're there!
288
289# Addendum: It turns out DAG 2.5 does this too, so we'll match DAG2.5 in here
290# also. This isn't such a bad thing, the DAG2.5 API is essentially the same as
291# DAG 3.0 and libtrace will use the same format_dagXX source for both
292libtrace_dag=false
293libtrace_dag_version=none
294
295if test "$with_dag" != no; then
296        AC_CHECK_LIB(dag, dag_open, dag_found=1, dag_found=0)
297        if test "$dag_found" = 1; then
298                ADD_LIBS="$ADD_LIBS -ldag"
299                LIBTRACE_LIBS="$LIBTRACE_LIBS -ldag"
300                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
301                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
302                libtrace_dag=true
303               
304                AC_DEFINE(DAG_VERSION,25,[defines the DAG driver version])
305                libtrace_dag_version=25
306        fi
307fi
308
309# TODO: turn the test part of the next block into a function, so it can be
310# called multiple times for $dag_root, /root/dag, /usr/local/lib
311dag_drv_v="DAG not present"
312
313# Now check for 2.4 DAG drivers which don't install as cleanly!
314if test "$with_dag" != no -a "$libtrace_dag" = false; then
315        AC_MSG_CHECKING(whether we have DAG 2.4 API instead)
316
317        if test -r "$dag_root/lib"; then
318                dag_lib_dir="$dag_root/lib"
319        else
320                dag_lib_dir="$dag_root"
321        fi
322       
323        if test -r "$dag_root/include"; then
324                dag_tools_dir="$dag_root/tools"
325                dag_include_dir="$dag_root/include"
326        else
327                dag_tools_dir="$dag_root"
328                dag_include_dir="$dag_root"
329        fi
330
331        if test -r "$dag_include_dir/dagapi.h" -a -r "$dag_lib_dir/libdag.a";
332        then
333                ADD_INCLS="$ADD_INCLS -I $dag_include_dir"
334                ADD_LIBS="$ADD_LIBS -ldag"
335                ADD_LDFLAGS="$ADD_LDFLAGS -L$dag_lib_dir"
336                DAG_TOOLS_DIR=$dag_tools_dir
337                AC_SUBST([DAG_TOOLS_DIR])
338                libtrace_dag=true
339               
340                AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
341                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
342                AC_DEFINE(DAG_VERSION, 24, [defines the DAG driver version])
343                libtrace_dag_version=24
344        else
345                if test "$want_dag" = yes; then
346                        AC_MSG_ERROR(DAG API not found under directory $dag_root
347; use --without-dag)
348                fi
349                libtrace_dag=false
350        fi
351        AC_MSG_RESULT($libtrace_dag)
352
353fi
354
355# Try to determine the DAG driver version
356#if test x"$libtrace_dag" = xtrue; then
357#       dag_drv_v="Unknown"
358#       files=`locate /usr/*dag*/VERSION`
359#       file_count=0
360#
361#       for i in $files; do
362#                if $file_count > 0; then
363#                        dag_drv_v="Indeterminate"
364#                        break
365#                fi
366#                dag_drv_v=`cat $i`
367#                file_count=$file_count+1
368#        done
369#fi
370#DAG_VERSION_NUM=$dag_drv_v
371
372
373# Checks for various "optional" libraries
374AC_CHECK_LIB(pthread, pthread_create, have_pthread=1, have_pthread=0)
375
376# Check for ncurses
377
378# These libraries have to be explicitly linked in OpenSolaris
379AC_SEARCH_LIBS(getservent, socket, have_socket=1, have_socket=0, -lnsl)
380LIBS=
381
382AC_SEARCH_LIBS(inet_ntop, nsl, have_nsl=1, have_nsl=0, -lsocket)
383LIBS=
384
385# Check to see if we have libdl - *BSD has built-in libdl
386AC_SEARCH_LIBS(dlopen,dl, dlfound=1,dlfound=0 )
387LIBS=
388
389if test "$dlfound" = 0; then
390        AC_MSG_ERROR("Unable to find dlopen. Please use LDFLAGS to specify the location of libdl and re-run configure")
391fi
392
393if test "$ac_cv_search_dlopen" != "none required"; then
394        LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_dlopen"
395fi
396
397if test "$have_pthread" = 1; then
398        LIBWANDIO_LIBS="$LIBWANDIO_LIBS -lpthread"
399        AC_DEFINE(HAVE_LIBPTHREAD, 1, [Set to 1 if pthreads are supported])
400fi
401
402
403if test "$have_nsl" = 1; then
404        if test "$ac_cv_search_inet_ntop" != "none required"; then
405                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_inet_ntop"
406                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_inet_ntop"
407        fi
408fi
409
410if test "$have_socket" = 1; then
411        if test "$ac_cv_search_getservent" != "none required"; then
412                LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_getservent"
413                LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_getservent"
414        fi
415fi
416
417
418# Stupid AC_SEARCH_LIB appends stuff to LIBS even when I don't want it to, so
419# just set libs to null here to avoid linking against them by default
420LIBS=
421
422# For now, the user has to explicitly ask for the LLVM stuff, as it's a bit
423# rough around the edges :(
424AC_ARG_WITH([llvm],
425        [AC_HELP_STRING([--with-llvm],
426                [support Just In Time compiler])],
427        use_llvm="yes",
428        use_llvm="no")
429JIT=no
430
431# Search for LLVM and the libraries that it requires
432if (test "$use_llvm" != "no"); then
433        AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
434
435        # XXX Hard coding the path is REALLY bad.
436        # llvm-gcc is installed in a stupid place in Debian / Ubuntu. Hard luck
437        # if you've installed it somewhere custom.
438        # Hopefully in future we can replace this with clang, which may or may
439        # not be installed somewhere intelligent.
440        AC_PATH_PROG(LLVM_GCC, llvm-gcc, no, /usr/lib/llvm/llvm/gcc-4.2/bin)
441
442        AC_LANG_PUSH([C++])
443        AC_CHECK_HEADERS([boost/lexical_cast.hpp], boost="yes", boost="no")
444        AC_LANG_POP([C++])
445
446               
447        if test "$boost" = "no"; then
448                AC_MSG_NOTICE([Unabled to find boost libraries.  JIT support disabled.])
449                JIT=no
450        elif test "$LLVM_CONFIG" = "no" ; then
451                AC_MSG_NOTICE([Unable to find llvm-config.  JIT support disabled.])
452                JIT=no
453        elif test "$LLVM_GCC" = "no"; then
454                AC_MSG_NOTICE([Unable to find llvm-gcc.  JIT support disabled.])
455                JIT=no
456        else
457                LIBCXXFLAGS="`$LLVM_CONFIG --cxxflags` $CXXFLAGS"
458                LIBTRACE_LIBS="$LIBRACE_LIBS `$LLVM_CONFIG --libs all`";
459                LDFLAGS="`$LLVM_CONFIG --ldflags` $LDFLAGS";
460                JIT=yes
461                AC_DEFINE(HAVE_LLVM, 1, [Set to 1 if you have LLVM installed])
462        fi
463fi
464
465AC_ARG_WITH([ncurses],
466        AC_HELP_STRING([--with-ncurses], [build tracetop (requires ncurses)]))
467
468AS_IF([test "x$with_ncurses" != "xno"],
469        [AC_SEARCH_LIBS(mvprintw, ncurses, have_ncurses=yes, have_ncurses=no)
470         LIBS=
471        ], [have_ncurses=no])
472
473AS_IF([test "x$have_ncurses" = "xyes"], [
474        if test "$ac_cv_search_mvprintw" != "none required"; then
475                TOOLS_LIBS="$TOOLS_LIBS $ac_cv_search_mvprintw"
476        fi
477        AC_DEFINE(HAVE_NCURSES, 1, "Compiled with ncurses support")
478        with_ncurses=yes],
479
480       
481        [AS_IF([test "x$with_ncurses" = "xyes"],
482                [AC_MSG_ERROR([ncurses requested but not found])])
483        AC_DEFINE(HAVE_NCURSES, 0, "Compiled with ncurses support")
484        with_ncurses=no]
485)
486                       
487AC_ARG_WITH([bzip2],
488        AC_HELP_STRING([--with-bzip2], [build with support for bzip2 compressed files]))
489
490AS_IF([test "x$with_bzip2" != "xno"],
491        [
492        AC_CHECK_LIB(bz2, BZ2_bzDecompressInit, have_bzip=yes, have_bzip=no)
493        ], [have_bzip=no])
494
495AS_IF([test "x$have_bzip" = "xyes"], [
496        if test "$ac_cv_lib_bz2_BZ2_bzDecompressInit" != "none required"; then
497                LIBWANDIO_LIBS="$LIBWANDIO_LIBS -lbz2"
498        fi
499        with_bzip2=yes
500        AC_DEFINE(HAVE_LIBBZ2, 1, "Compiled with bzip2 support")],
501       
502        [AS_IF([test "x$with_bzip2" = "xyes"],
503                [AC_MSG_ERROR([bzip2 requested but not found])])
504        AC_DEFINE(HAVE_LIBBZ2, 0, "Compiled with bzip2 support")
505        with_bzip2=no]
506)
507
508AC_ARG_WITH([zlib],
509        AC_HELP_STRING([--with-zlib], [build with support for zlib compressed files]))
510
511AS_IF([test "x$with_zlib" != "xno"],
512        [
513        AC_CHECK_LIB(z, deflate, have_zlib=yes, have_zlib=no)
514        ], [have_zlib=no])
515
516AS_IF([test "x$have_zlib" = "xyes"], [
517        if test "$ac_cv_lib_z_deflate" != "none required"; then
518                LIBWANDIO_LIBS="$LIBWANDIO_LIBS -lz"
519        fi
520        AC_DEFINE(HAVE_LIBZ, 1, "Compiled with zlib support")
521        with_zlib=yes],
522
523       
524        [AS_IF([test "x$with_zlib" = "xyes"],
525                [AC_MSG_ERROR([zlib requested but not found])])
526        AC_DEFINE(HAVE_LIBZ, 0, "Compiled with zlib support")
527        with_zlib=no]
528)
529
530AC_ARG_WITH([lzo],
531        AC_HELP_STRING([--with-lzo], [build with support for writing lzo compressed files]))
532
533AS_IF([test "x$with_lzo" != "xno"],
534        [
535        AC_CHECK_LIB(lzo2, lzo1x_1_compress, have_lzo=yes, have_lzo=no)
536        ], [have_lzo=no])
537
538AS_IF([test "x$have_lzo" = "xyes"], [
539        if test "$ac_cv_lib_lzo2_lzo1x_1_compress" != "none required"; then
540                LIBWANDIO_LIBS="$LIBWANDIO_LIBS -llzo2"
541        fi
542        AC_DEFINE(HAVE_LIBLZO2, 1, "Compiled with lzo2 support")
543        with_lzo=yes],
544
545       
546        [AS_IF([test "x$with_lzo" = "xyes"],
547                [AC_MSG_ERROR([lzo requested but not found])])
548        AC_DEFINE(HAVE_LIBLZO2, 0, "Compiled with lzo2 support")
549        with_lzo=no]
550)
551
552
553# Define automake conditionals for use in our Makefile.am files
554AM_CONDITIONAL([HAVE_BPF_CAPTURE], [test "$ac_cv_have_decl_BIOCSETIF" = yes ])
555AM_CONDITIONAL([HAVE_DAG], [test "$libtrace_dag" = true])
556AM_CONDITIONAL([DAG2_4], [test "$libtrace_dag_version" = 24])
557AM_CONDITIONAL([DAG2_5], [test "$libtrace_dag_version" = 25])
558AM_CONDITIONAL([HAVE_NETPACKET_PACKET_H], [test "$libtrace_netpacket_packet_h" = true])
559AM_CONDITIONAL([HAVE_LIBGDC], [test "$ac_cv_header_gdc_h" = yes])
560AM_CONDITIONAL([HAVE_LLVM], [test "x$JIT" != "xno" ])
561AM_CONDITIONAL([HAVE_NCURSES], [test "x$with_ncurses" != "xno"])
562AM_CONDITIONAL([HAVE_BZLIB], [test "x$with_bzip2" != "xno"])
563AM_CONDITIONAL([HAVE_ZLIB], [test "x$with_zlib" != "xno"])
564AM_CONDITIONAL([HAVE_LZO], [ test "x$with_lzo" != "xno"])
565
566# Check for miscellaneous programs
567AC_CHECK_PROG([libtrace_doxygen], [doxygen], [true], [false])
568
569AM_CONDITIONAL(HAS_DOXYGEN, [test x"$libtrace_doxygen" = xtrue])
570
571# Set all our output variables
572AC_SUBST([LIBTRACE_LIBS])
573AC_SUBST([LIBPKTDUMP_LIBS])
574AC_SUBST([LIBWANDIO_LIBS])
575AC_SUBST([TOOLS_LIBS])
576#AC_SUBST([ADD_LIBS])
577AC_SUBST([ADD_LDFLAGS])
578AC_SUBST([ADD_INCLS])
579AC_SUBST([LTLIBOBJS])
580AC_SUBST([MANPAGES])
581AC_SUBST([PACKAGE_VERSION])
582AC_SUBST([LIBTRACE_MAJOR])
583AC_SUBST([LIBTRACE_MID])
584AC_SUBST([LIBTRACE_MINOR])
585AC_SUBST([DAG_VERSION_NUM])
586AC_SUBST([HAVE_BPF_CAPTURE])
587AC_SUBST([HAVE_LIBGDC])
588AC_SUBST([HAVE_LLVM])
589AC_SUBST([HAVE_NCURSES])
590AC_SUBST([LIBCFLAGS])
591AC_SUBST([LIBCXXFLAGS])
592
593
594# Finally, output our Makefiles
595AC_OUTPUT
596
597# Function for reporting whether an option was set or not
598reportopt() {
599        if test x"$2" = xtrue -o x"$2" = xyes; then
600                AC_MSG_NOTICE([$1: Yes])
601        else
602                AC_MSG_NOTICE([$1: No])
603        fi
604}
605
606
607# Report which configure options were set
608echo
609AC_MSG_NOTICE([Libtrace version $PACKAGE_VERSION])
610if test "$pcapcreate" = 1; then
611        AC_MSG_NOTICE([Compiled with PCAP support: >= 1.0])
612else
613        AC_MSG_NOTICE([Compiled with PCAP support: < 1.0])
614fi
615
616reportopt "Compiled with compressed trace (zlib) support" $with_zlib
617reportopt "Compiled with compressed trace (bz2) support" $with_bzip2
618reportopt "Compiled with compressed trace (lzo write only) support" $with_lzo
619if test x"$libtrace_dag" = xtrue; then
620        if test "$libtrace_dag_version" = 24; then
621                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.4])
622        elif test "$libtrace_dag_version" = 30; then
623                AC_MSG_NOTICE([Compiled with DAG live capture support: 3.0])
624        else
625                AC_MSG_NOTICE([Compiled with DAG live capture support: 2.5])
626        fi     
627else
628        AC_MSG_NOTICE([Compiled with DAG live capture support: No])
629fi
630reportopt "Compiled with LLVM BPF JIT support" $JIT
631reportopt "Building man pages/documentation" $libtrace_doxygen
632reportopt "Building tracetop (requires libncurses)" $with_ncurses
633
634# Report any errors relating to missing bison, flex, etc.
635echo
636ac_cv_errcount=0;
637if test -z "$YACC"; then
638        AC_MSG_WARN(bison or yacc not found. Please install bison before continuing)
639        ac_cv_errcount=$((ac_cv_errcount + 1))
640fi
641
642if test "x$LEX" != xflex -a "x$LEX" != xlex; then
643        AC_MSG_WARN(flex or lex not found. Please install flex before continuing)
644        ac_cv_errcount=$((ac_cv_errcount + 1))
645fi
646
647if test $ac_cv_errcount -gt 0; then
648        AC_MSG_ERROR(Critical packages are missing and compilation will fail. Please install the packages listed above and rerun ./configure)
649fi
650
Note: See TracBrowser for help on using the repository browser.