source: configure.in @ 437d002

4.0.1-hotfixescachetimestampsdevelopdpdk-ndagetsilivegetfragoffhelplibtrace4ndag_formatpfringrc-4.0.1rc-4.0.2rc-4.0.3rc-4.0.4ringdecrementfixringperformanceringtimestampfixes
Last change on this file since 437d002 was 437d002, checked in by Daniel Lawson <dlawson@…>, 16 years ago

updated configure.in to generare nice messages telling us what we configured libtrace with

  • Property mode set to 100644
File size: 7.9 KB
Line 
1# Process this file with autoconf to produce a configure script.
2AC_INIT(libtrace,2.0.23,[libtrace@wand.net.nz],libtrace)
3AC_CONFIG_SRCDIR(lib/trace.c)
4AM_INIT_AUTOMAKE(libtrace, 2.0.23)
5
6AC_CONFIG_FILES([Makefile lib/Makefile docs/Makefile])
7dnl GNU C library
8dnl AC_GNU_SOURCE
9
10AM_CONFIG_HEADER(config.h)
11#AC_CONFIG_HEADERS([config.h])
12dnl Checks for programs.
13AC_PROG_CC
14AC_PROG_INSTALL
15AC_PROG_LIBTOOL
16
17
18
19# Checks for header files.
20AC_HEADER_STDC
21dnl AC_CHECK_HEADERS(errno.h stdlib.h stdio.h assert.h string.h netinet/in.h assert.h errno.h fcntl.h net/ethernet.h netdb.h pcap.h stdio.h stdlib.h string.h sys/stat.h sys/types.h sys/socket.h sys/un.h unistd.h time.h sys/ioctl.h net/bpf.h pcap.h zlib.h pcap-bpf.h)
22AC_CHECK_HEADERS(pcap.h pcap-int.h pcap-bpf.h net/bpf.h zlib.h sys/limits.h stddef.h inttypes.h limits.h net/ethernet.h )
23
24AC_CHECK_HEADERS(netinet/in.h)
25
26AC_CHECK_HEADER(net/if.h,
27                AC_DEFINE(HAVE_NET_IF_H,1,[We have net/if.h]), [],
28[#include <sys/types.h>
29 #include <sys/socket.h>
30])
31
32
33AC_CHECK_HEADER(netinet/if_ether.h,
34                AC_DEFINE(HAVE_NETINET_IF_ETHER_H,1,[We have netinet/if_ether.h]), [],
35[
36 #include <sys/types.h>
37 #include <sys/socket.h>
38 #include <netinet/in.h>
39 #include <net/if.h>
40])
41
42AC_CHECK_HEADER(net/if_arp.h,
43                AC_DEFINE(HAVE_NET_IF_ARP_H,1,[We have net/if_arp.h]), [],
44[
45 #include <sys/types.h>
46 #include <sys/socket.h>
47 #include <netinet/in.h>
48 #include <net/if.h>
49])
50
51       
52# Checking for the right bpf header to include
53AC_MSG_CHECKING([where the bpf headers are kept])
54echo ""
55bpfh=no
56AC_CHECK_HEADER(pcap-bpf.h,
57        [AC_DEFINE([HAVE_PCAP_BPF_H]) bpfh=pcap-bpf.h])
58if test $bpfh = no; then
59AC_CHECK_HEADER(net/bpf.h,
60        [AC_DEFINE([HAVE_NET_BPF_H]) bpfh=net/bpf.h])
61fi
62
63if test $bpfh = no; then
64  AC_MSG_RESULT([No BPF headers, compiling without support for BPF filters])
65  AC_DEFINE(HAVE_BPF,0,[Conditional for building bpf support])
66  libtrace_bpf=false
67else
68  AC_MSG_RESULT([Using $bpfh])
69  AC_DEFINE(HAVE_BPF,1,[Conditional for building bpf support])
70  libtrace_bpf=true
71fi
72
73
74# Check for various broken functions
75AC_FUNC_MALLOC
76AC_FUNC_REALLOC
77
78# *BSD doesn't have strndup. Currently provide our own.
79AC_REPLACE_FUNCS(strndup)
80
81# Check to see if we have libpcap
82AC_CHECK_LIB(pcap,libtrace_pcap,
83             libtrace_pcap=true,
84             libtrace_pcap=false)
85
86if test "$libtrace_pcap" = true; then
87    AC_DEFINE(HAVE_PCAP,1,[Conditional for building PCAP support])
88    ADD_LIBS="$ADD_LIBS  -lpcap"
89else
90    AC_DEFINE(HAVE_PCAP,0,[Conditional for building PCAP support])
91fi     
92
93# Earlier versions of pcap don't have pcap_open_dead. EG: the one OpenBSD
94# ships with. Even Debian Woody is more up to date.
95AC_CHECK_LIB(pcap,pcap_open_dead,
96        have_pcap_open_dead=true,
97        have_pcap_open_dead=false)
98
99if test "$have_pcap_open_dead" = false; then
100        AC_REPLACE_FUNCS(pcap_open_dead)
101fi
102   
103# Versions of libpcap earlier than 0.8 don't have pcap_dump_flush
104AC_CHECK_LIB(pcap,pcap_dump_flush,
105             have_pcap_dump_flush=true,
106             have_pcap_dump_flush=false)
107
108if test "$have_pcap_dump_flush" = false; then
109        AC_REPLACE_FUNCS(pcap_dump_flush)
110fi
111
112# Checks for typedefs, structures, and compiler characteristics.
113AC_C_CONST
114AC_C_INLINE
115AC_C_BIGENDIAN
116AC_TYPE_SIZE_T
117AC_HEADER_TIME
118AC_SYS_LARGEFILE
119
120# Checks for library functions.
121AC_PROG_GCC_TRADITIONAL
122AC_CHECK_FUNCS(socket strdup)
123
124# configure time options for man pages
125AC_ARG_WITH(man,
126            AC_HELP_STRING([--with-man],
127                           [install man pages by default]),
128
129             if test "$withval" = yes
130             then
131                     MANPAGES="docs/man/man3/[a-zA-Z]*.3]"
132             else
133                     MANPAGES=""
134             fi
135)
136
137# configure time options for use of DAG cards
138# borrowed from libpcap!
139AC_ARG_WITH(dag,
140            AC_HELP_STRING([--with-dag[=DIR]],
141                           [include DAG support (located in directory DIR, if supplied)]),
142[
143        if test "$withval" = no
144        then
145                want_dag=no
146        elif test "$withval" = yes
147        then
148                want_dag=yes
149                dag_root=/root/dag
150        else
151                want_dag=yes
152                dag_root=$withval
153        fi
154],[
155        #
156        # Use DAG API if present, otherwise don't
157        #
158        want_dag=ifpresent
159        dag_root=/root/dag/
160])
161
162# turn the test part of the next block into a function, so it can be
163# called multiple times for $dag_root, /root/dag, /usr/local/lib
164libtrace_dag=false
165libtrace_dag2_4=false
166if test "$with_dag" != no; then
167        AC_MSG_CHECKING(whether we have DAG API)
168
169        if test -r "$dag_root/lib"; then
170                dag_lib_dir="$dag_root/lib"
171        else
172                dag_lib_dir="$dag_root"
173        fi
174       
175        if test -r "$dag_root/tools" -a -r "$dag_root/include"; then
176                dag_tools_dir="$dag_root/tools"
177                dag_include_dir="$dag_root/include"
178        else
179                dag_tools_dir="$dag_root"
180                dag_include_dir="$dag_root"
181        fi
182
183        if test -r "$dag_include_dir/dagapi.h" -a -r "$dag_lib_dir/libdag.a";
184        then
185                ADD_INCLS="$ADD_INCLS -I $dag_include_dir"
186                ADD_LIBS="$ADD_LIBS -ldag"
187                ADD_LDFLAGS="$ADD_LDFLAGS -L$dag_lib_dir"
188                DAG_TOOLS_DIR=$dag_tools_dir
189                AC_SUBST([DAG_TOOLS_DIR])
190                libtrace_dag=true
191               
192                AC_DEFINE(HAVE_DAG_API, 1, [define if you have a DAG API])
193                AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG support])
194        else
195                if test "$want_dag" = yes; then
196                        AC_MSG_ERROR(DAG API not found under directory $dag_root
197; use --without-dag)
198                fi
199                libtrace_dag=false
200        fi
201        AC_MSG_RESULT($libtrace_dag)
202       
203        AC_MSG_CHECKING(if we are using DAG 2.4)
204        if grep '2.4.' $dag_root/VERSION > /dev/null 2>&1; then
205                libtrace_dag2_4=true
206        else
207                libtrace_dag2_4=false
208        fi
209        AC_MSG_RESULT($libtrace_dag2_4)
210else
211        AC_DEFINE(HAVE_DAG,0,[conditional for building with DAG support])
212fi
213
214AM_CONDITIONAL(HAVE_DAG, test x$libtrace_dag = xtrue)
215AM_CONDITIONAL(DAG2_4, test x$libtrace_dag2_4 = xtrue)
216
217
218# Check for miscellaneous programs
219AC_CHECK_PROG([libtrace_doxygen], [doxygen], [true], [false])
220
221AM_CONDITIONAL(HAS_DOXYGEN, [test x"$libtrace_doxygen" = xtrue])
222
223
224
225
226AC_ARG_WITH([zlib],
227    AC_HELP_STRING([--with-zlib],
228                               [name of zlib library (default is z)]),
229        [ac_cv_use_zlib=$withval],
230    [ac_cv_use_zlib=z])
231
232AC_ARG_WITH([zlib-path],
233    AC_HELP_STRING([--with-zlib-path],
234                   [location of zlib library (default is /usr/lib)]),
235    [ac_cv_use_zlib_path=$withval],
236    [ac_cv_use_zlib_path=/usr/lib])
237
238if test "$ac_cv_use_zlib" != no; then
239    ADD_LIBS="$ADD_LIBS -l$ac_cv_use_zlib"
240   
241    zlib_lib_file="${ac_cv_use_zlib_path}/lib${ac_cv_use_zlib}.so"
242
243    # if the library is in /usr/lib/, then just use AC_CHECK_LIB
244    if test x"${ac_cv_use_zlib_path}" == x"/usr/lib"; then
245            AC_CHECK_LIB(${ac_cv_use_zlib}, gzopen,
246                         have_libzlib=yes,
247                         have_libzlib=no)
248            if test x"{have_libzlib}" == xno; then
249                AC_MSG_NOTICE([Cannot find zlib library $zlib_lib_file.])
250                AC_MSG_ERROR([Exiting]);
251            fi
252    else
253        ADD_LDFLAGS="$ADD_LDFLAGS -L$ac_cv_use_zlib_path"
254        # if it's not in /usr/lib/, check manually. This isn't nice
255        # and will probably break.
256        if test ! -r "$ac_cv_use_zlib_path" -o ! -r "$zlib_lib_file"; then
257                AC_MSG_NOTICE([Cannot find zlib library $zlib_lib_file.])
258                AC_MSG_ERROR([Exiting]);
259        fi
260    fi
261    AC_DEFINE(HAVE_ZLIB,1,[Conditional for building zlib support])
262    libtrace_zlib=true
263else
264    AC_DEFINE(HAVE_ZLIB,0,[Conditional for building zlib support])   
265    libtrace_zlib=false
266fi
267
268
269
270AC_SUBST([ADD_LIBS])
271AC_SUBST([ADD_LDFLAGS])
272AC_SUBST([ADD_INCLS])
273AC_SUBST([LTLIBOBJS])
274AC_SUBST([MANPAGES])
275
276dnl and finally, output our Makefiles
277AC_OUTPUT
278
279function reportopt() {
280        if test x"$2" = xtrue; then
281                AC_MSG_NOTICE([$1: Yes])
282        else
283                AC_MSG_NOTICE([$1: No])
284        fi
285}
286
287reportopt "Compiled with BPF filter support" $libtrace_bpf
288reportopt "Compiled with PCAP support" $libtrace_pcap
289reportopt "Compiled with compressed trace (zlib) support" $libtrace_zlib
290reportopt "Compiled with DAG support (libdag)" $libtrace_dag
291reportopt "Compiled with DAG support (DAG 2.4)" $libtrace_dag2_4
292reportopt "Building man pages/documentation" $libtrace_doxygen
293
Note: See TracBrowser for help on using the repository browser.