Context Navigation

source: configure.in @ 0ae7ba2

develop

Last change on this file since 0ae7ba2 was 0ae7ba2, checked in by Shane Alcock <salcock@…>, 2 years ago

Prefer an installed .so over a .a for libdpdk.

We sometimes run into issues with building the libtrace tools
if we link against the .a (e.g. if we've installed dpdk-dev on
Debian jessie).

I think we're getting close to the point where we can consider
ignoring the .a altogether -- the .so is installed by default
by the Debian packages and our own DPDK instructions tell
people how to build the shared library -- so maybe we can
reasonably expect that there will be a .so available if we need
it and if not, then we can just build without dpdk support?

Property mode set to 100644

File size: 22.9 KB

Line
1	# Process this file with autoconf to produce a configure script.
2
3	# Now you only need to update the version number in two places - below,
4	# and in the README
5
6	AC_INIT([libtrace],[4.0.5],[contact@wand.net.nz],[libtrace])
7
8	LIBTRACE_MAJOR=4
9	LIBTRACE_MID=0
10	LIBTRACE_MINOR=5
11
12	# OpenSolaris hides libraries like libncurses in /usr/gnu/lib, which is not
13	# searched by default - add it to LDFLAGS so we at least have a chance of
14	# finding it
15	if test -d "/usr/gnu/lib"; then
16	LDFLAGS+=" -L/usr/gnu/lib"
17	fi
18
19	AC_CONFIG_MACRO_DIR([m4])
20	AC_CONFIG_SRCDIR(lib/trace.c)
21	AM_INIT_AUTOMAKE([subdir-objects])
22
23	# Make sure we use the relatively silent automake output
24	m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
25
26	# Define our libtrace version number externally so we can use it in the source
27	# as well, if needed.
28	AC_DEFINE([LIBTRACE_MAJOR],${LIBTRACE_MAJOR},[libtrace major version])
29	AC_DEFINE([LIBTRACE_MID],${LIBTRACE_MID},[libtrace mid version])
30	AC_DEFINE([LIBTRACE_MINOR],${LIBTRACE_MINOR},[libtrace minor version])
31
32	# These are all the files we want to be built for us by configure
33	AC_CONFIG_FILES([Makefile lib/Makefile docs/Makefile libpacketdump/Makefile
34	tools/Makefile tools/traceanon/Makefile tools/tracepktdump/Makefile
35	tools/tracemerge/Makefile tools/tracereport/Makefile
36	tools/tracertstats/Makefile tools/tracesplit/Makefile
37	tools/tracestats/Makefile tools/tracetop/Makefile
38	tools/tracereplay/Makefile tools/tracediff/Makefile
39	tools/traceends/Makefile
40	examples/Makefile examples/skeleton/Makefile examples/rate/Makefile
41	examples/stats/Makefile examples/tutorial/Makefile examples/parallel/Makefile
42	docs/libtrace.doxygen
43	lib/libtrace.h
44	])
45
46
47	# Function that checks if the C++ compiler actually works - there's a bit of
48	# oversight in autoconf that will set the C++ compiler to g++ if no compiler
49	# is found, even if g++ is not present! So we need an extra test to make sure
50	# that the compiler works :(
51
52	AC_DEFUN([rw_PROG_CXX_WORKS],
53	[AC_REQUIRE([AC_PROG_CXX])dnl
54	AC_CACHE_CHECK([whether the C++ compiler works],
55	[rw_cv_prog_cxx_works],
56	[AC_LANG_PUSH([C++])
57	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
58	[rw_cv_prog_cxx_works=yes],
59	[rw_cv_prog_cxx_works=no])
60	AC_LANG_POP([C++])])
61	])
62
63	# Put all our automake definitions in config.h
64	AM_CONFIG_HEADER([config.h])
65
66	# Checks for C and C++ compilers
67	AC_PROG_CC
68	AC_PROG_CXX
69	rw_PROG_CXX_WORKS
70
71	if test "$rw_cv_prog_cxx_works" = "no"; then
72	AC_MSG_ERROR("Failed to find working C++ compiler")
73	fi
74
75	# Checking for 'install'
76	AC_PROG_INSTALL
77
78	# Checking for bison and flex
79	AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc)
80	AM_PROG_LEX
81
82	# All our source files for function replacements are in lib/
83	AC_CONFIG_LIBOBJ_DIR(lib)
84
85	# Check for various "replacement" functions
86	AC_FUNC_MALLOC
87	AC_FUNC_REALLOC
88
89	# Checks for typedefs, structures, and compiler characteristics.
90	AC_C_CONST
91	AC_C_INLINE
92	AC_C_BIGENDIAN
93	AC_TYPE_SIZE_T
94	AC_HEADER_TIME
95	AC_SYS_LARGEFILE
96
97	LIBPKTDUMP_LIBS="-ltrace "
98	ADD_LDFLAGS="$ADD_LDFLAGS -L\$(abs_top_srcdir)/lib"
99	LIBTRACE_LIBS=""
100	TOOLS_LIBS=""
101
102	CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wextra -DLT_BUILDING_DLL=1"
103	CXXFLAGS="$CXXFLAGS -Wall -DLT_BUILDING_DLL=1"
104
105	# Check for -fvisibility
106	gl_VISIBILITY
107
108	gcc_PACKED
109	gcc_DEPRECATED
110	gcc_UNUSED
111	gcc_PURE
112	gcc_FORMAT
113
114	# Check for gcc style TLS (__thread)
115	gcc_TLS
116
117	# Check for libtool
118	AC_PROG_LIBTOOL
119
120	# Checks for library functions.
121	AC_PROG_GCC_TRADITIONAL
122
123	# Fail if any of these functions are missing
124	AC_CHECK_DECLS([strdup, strlcpy, strcasecmp, strncasecmp, snprintf, vsnprintf, strndup])
125	AC_CHECK_DECLS([socket, recvmmsg], [], [], [[#define _GNU_SOURCE 1
126	#include <sys/socket.h>]])
127	AC_CHECK_SIZEOF([long int])
128
129
130	# Checks for header files.
131	AC_HEADER_STDC
132	AC_CHECK_HEADERS(pcap.h pcap-int.h pcap-bpf.h net/bpf.h sys/limits.h stddef.h inttypes.h limits.h net/ethernet.h sys/prctl.h)
133
134
135	# OpenSolaris puts ncurses.h in /usr/include/ncurses rather than /usr/include,
136	# so check for that
137	AC_CHECK_HEADERS(ncurses.h,,[missing_ncurses=true])
138
139	if test "x$missing_ncurses" = xtrue; then
140	if test -f "/usr/include/ncurses/ncurses.h"; then
141	AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Has nested ncurses header])
142	fi
143	fi
144
145
146	# Check for the presence of various networking headers and define appropriate
147	# macros
148	AC_CHECK_HEADERS(netinet/in.h)
149	AC_CHECK_HEADERS(netpacket/packet.h,[
150	libtrace_netpacket_packet_h=true
151	AC_DEFINE(HAVE_NETPACKET_PACKET_H,1,[has net])
152	])
153	AC_CHECK_HEADER(net/if.h,
154	AC_DEFINE(HAVE_NET_IF_H,1,[has net/if.h header]),,[
155	#include <sys/types.h>
156	#include <sys/socket.h>
157	])
158
159	AC_CHECK_HEADER(netinet/ether.h,
160	AC_DEFINE(HAVE_NETINET_ETHER_H,1,[has netinet/ether.h header]),,[
161	#include <sys/types.h>
162	#include <sys/socket.h>
163	#include <netinet/in.h>
164	#include <net/if.h>
165	])
166
167	AC_CHECK_HEADER(netinet/if_ether.h,
168	AC_DEFINE(HAVE_NETINET_IF_ETHER_H,1,[has netinet/if_ether.h]),,[
169	#include <sys/types.h>
170	#include <sys/socket.h>
171	#include <netinet/in.h>
172	#include <net/if.h>
173	])
174
175	AC_CHECK_HEADER(net/if_arp.h,
176	AC_DEFINE(HAVE_NET_IF_ARP_H,1,[has net/if_arp.h]),,[
177	#include <sys/types.h>
178	#include <sys/socket.h>
179	#include <netinet/in.h>
180	#include <net/if.h>
181	])
182
183	# Check for sdl_len in sockaddr_dl - sockaddr_dl is used on BSD systems
184	if test "$libtrace_netpacket_packet_h" != "true"; then
185	AC_CHECK_MEMBER([struct sockaddr_dl.sdl_len],
186	AC_DEFINE(HAVE_SDL_LEN,1,[Has sdl_len in sockaddr_dl]),,[
187	#include <sys/types.h>
188	#include <sys/socket.h>
189	#include <net/if_dl.h>
190	])
191	fi
192
193	# Checking for the right bpf header to include
194	AC_CHECK_HEADER(pcap-bpf.h)
195	AC_CHECK_HEADER(net/bpf.h)
196
197	# Checking for libgdc
198	AC_CHECK_HEADER(gdc.h,AC_DEFINE(HAVE_LIBGDC,1,[has gdc.h]))
199
200	# Check for libwandio (no longer bundled with libtrace)
201	AC_CHECK_LIB(wandio,wandio_wflush,wandiofound=1,wandiofound=0)
202	if test "$wandiofound" = 0; then
203	AC_MSG_ERROR(libwandio 4.0.0 or better is required to compile this version of libtrace. If you have installed libwandio in a non-standard location please use LDFLAGS to specify the location of the library. WANDIO can be obtained from http://research.wand.net.nz/software/libwandio.php)
204	else
205	LIBTRACE_LIBS="$LIBTRACE_LIBS -lwandio"
206	TOOLS_LIBS="$TOOLS_LIBS -lwandio"
207	AC_DEFINE([HAVE_LIBWANDIO],1,[compile with libwandio support])
208	fi
209
210	AC_CHECK_LIB(crypto, EVP_EncryptInit_ex, cryptofound=1, cryptofound=0)
211	if test "$cryptofound" = 1; then
212	AC_CHECK_HEADER(openssl/evp.h, cryptofound=1, cryptofound=0)
213	fi
214	AC_CHECK_LIB(tasn1, asn1_array2tree, asn1found=1, asn1found=0)
215
216	# Check for libpcap
217	AC_CHECK_LIB(pcap,pcap_next_ex,pcapfound=1,pcapfound=0)
218	AC_CHECK_LIB(pcap,pcap_create,pcapcreate=1,pcapcreate=0)
219	AC_CHECK_LIB(pcap,pcap_set_immediate_mode,pcapimmediate=1,pcapimmediate=0)
220	AC_CHECK_DECLS([BIOCSETIF],,,[
221	#include <sys/types.h>
222	#include <sys/time.h>
223	#include <sys/ioctl.h>
224	#include <net/bpf.h>
225	])
226
227	AC_ARG_ENABLE(memory-debugging,
228	AS_HELP_STRING(--enable-memory-debugging, prints internal memory statistics),[
229	if test "$HAVE_TLS" = 1
230	then
231	AC_DEFINE([ENABLE_MEM_STATS], 1, [print debug memory statistics])
232	fi
233	],[])
234
235	# Configure options for man pages
236	AC_ARG_WITH(man,
237	AS_HELP_STRING(--with-man,install man pages by default),[
238	if test "$withval" = yes
239	then
240	MANPAGES="docs/man/man3/[a-zA-Z]*.3"
241	else
242	MANPAGES=""
243	fi
244	])
245
246	# Complain if we didn't find a suitable libpcap
247	if test "$pcapfound" = 0; then
248	AC_MSG_ERROR(libpcap0.8 or greater is required to compile libtrace. If you have installed it in a non-standard location please use LDFLAGS to specify the location of the library)
249	else
250	TOOLS_LIBS="$TOOLS_LIBS -lpcap"
251	LIBTRACE_LIBS="$LIBTRACE_LIBS -lpcap"
252	AC_DEFINE([HAVE_LIBPCAP],1,[compile with libpcap support])
253
254	LIBS="-lpcap"
255	AC_CHECK_FUNCS(pcap_inject pcap_sendpacket pcap_setnonblock)
256	LIBS=""
257
258	fi
259
260	if test "$pcapcreate" = 1; then
261	AC_DEFINE([HAVE_PCAP_CREATE],1,[compile with libpcap 1.0 support])
262	fi
263
264	if test "$pcapimmediate" = 1; then
265	AC_DEFINE([HAVE_PCAP_IMMEDIATE],1,[able to use pcap_set_immediate_mode])
266	fi
267
268	# Configure options for use of DAG cards
269	# Originally borrowed from libpcap, but extended quite a bit :)
270	# More details on how this check works:
271	# http://wand.net.nz/trac/libtrace/wiki/DAGNotes
272
273	AC_ARG_WITH(dag,
274	AS_HELP_STRING(--with-dag[=DIR],include DAG live capture support (located in directory DIR, if supplied)),
275	[
276	if test "$withval" = no
277	then
278	want_dag=no
279	elif test "$withval" = yes
280	then
281	want_dag=yes
282	dag_root=/usr/local/dag
283	else
284	want_dag=yes
285	dag_root=$withval
286	fi
287	],[
288	#
289	# Use DAG API if present, otherwise don't
290	#
291	want_dag=ifpresent
292	dag_root=/usr/local/dag
293	])
294
295	# DAG 3.0 actually puts header files and shared libraries into sensible
296	# places now, so we should be able to do a simple CHECK_LIB to see if
297	# they're there!
298
299	# Addendum: It turns out DAG 2.5 does this too, so we'll match DAG2.5 in here
300	# also. This isn't such a bad thing, the DAG2.5 API is essentially the same as
301	# DAG 3.0 and libtrace will use the same format_dagXX source for both
302	libtrace_dag=false
303	libtrace_dag_version=none
304
305	if test "$with_dag" != no; then
306	AC_CHECK_LIB(dag, dag_open, dag_found=1, dag_found=0)
307	if test "$dag_found" = 1; then
308	ADD_LIBS="$ADD_LIBS -ldag"
309	LIBTRACE_LIBS="$LIBTRACE_LIBS -ldag"
310	AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
311	AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
312	libtrace_dag=true
313
314	AC_DEFINE(DAG_VERSION,25,[defines the DAG driver version])
315	libtrace_dag_version=25
316
317	AC_CHECK_HEADERS(dag_config_api.h,[csapi_found=1],,)
318	if test "$csapi_found" = 1; then
319	LIBTRACE_LIBS="$LIBTRACE_LIBS -ldagconf"
320	fi
321	fi
322	fi
323
324	# TODO: turn the test part of the next block into a function, so it can be
325	# called multiple times for $dag_root, /root/dag, /usr/local/lib
326	dag_drv_v="DAG not present"
327
328	# Now check for 2.4 DAG drivers which don't install as cleanly!
329	if test "$with_dag" != no -a "$libtrace_dag" = false; then
330	AC_MSG_CHECKING(whether we have DAG 2.4 API instead)
331
332	if test -r "$dag_root/lib"; then
333	dag_lib_dir="$dag_root/lib"
334	else
335	dag_lib_dir="$dag_root"
336	fi
337
338	if test -r "$dag_root/include"; then
339	dag_tools_dir="$dag_root/tools"
340	dag_include_dir="$dag_root/include"
341	else
342	dag_tools_dir="$dag_root"
343	dag_include_dir="$dag_root"
344	fi
345
346	if test -r "$dag_include_dir/dagapi.h" -a -r "$dag_lib_dir/libdag.a";
347	then
348	ADD_INCLS="$ADD_INCLS -I $dag_include_dir"
349	ADD_LIBS="$ADD_LIBS -ldag"
350	ADD_LDFLAGS="$ADD_LDFLAGS -L$dag_lib_dir"
351	DAG_TOOLS_DIR=$dag_tools_dir
352	AC_SUBST([DAG_TOOLS_DIR])
353	libtrace_dag=true
354
355	AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
356	AC_DEFINE(HAVE_DAG,1,[conditional for building with DAG live capture support])
357	AC_DEFINE(DAG_VERSION, 24, [defines the DAG driver version])
358	libtrace_dag_version=24
359	else
360	if test "$want_dag" = yes; then
361	AC_MSG_ERROR(DAG API not found under directory $dag_root
362	; use --without-dag)
363	fi
364	libtrace_dag=false
365	fi
366	AC_MSG_RESULT($libtrace_dag)
367
368	fi
369
370	# Try to determine the DAG driver version
371	#if test x"$libtrace_dag" = xtrue; then
372	# dag_drv_v="Unknown"
373	# files=`locate /usr/dag/VERSION`
374	# file_count=0
375	#
376	# for i in $files; do
377	# if $file_count > 0; then
378	# dag_drv_v="Indeterminate"
379	# break
380	# fi
381	# dag_drv_v=`cat $i`
382	# file_count=$file_count+1
383	# done
384	#fi
385	#DAG_VERSION_NUM=$dag_drv_v
386
387	# Check for DPDK
388	AC_ARG_WITH(dpdk,
389	AS_HELP_STRING(--with-dpdk,include DPDK live capture support (From either the RTE_SDK/_TARGET environment variable or the dpdk-dev package)),
390	[
391	if test "$withval" = no
392	then
393	want_dpdk=no
394	else
395	want_dpdk=ifpresent
396	fi
397	],[
398	# Default to building without DPDK format
399	want_dpdk=no
400	])
401
402	libtrace_dpdk=false
403	if test "$want_dpdk" != no; then
404	# So instead simply check for existence
405	if test "$RTE_SDK" != ""; then
406	AC_CHECK_FILE("$RTE_SDK/$RTE_TARGET/lib/libdpdk.so", dpdk_found="dpdk", dpdk_found=0)
407	fi
408	if test "$dpdk_found" = 0 -a "$RTE_SDK" != ""; then
409	AC_CHECK_FILE("$RTE_SDK/$RTE_TARGET/lib/libintel_dpdk.a", dpdk_found=":libintel_dpdk.a", dpdk_found=0)
410	fi
411	# DPDK 2.1.0+ renames this to libdpdk from libintel_dpdk
412	if test "$dpdk_found" = 0 -a "$RTE_SDK" != ""; then
413	AC_CHECK_FILE("$RTE_SDK/$RTE_TARGET/lib/libdpdk.a", dpdk_found=":libdpdk.a", dpdk_found=0)
414	fi
415	if test "$dpdk_found" = 0 -a "$RTE_SDK" != ""; then
416	AC_CHECK_LIB(dpdk, rte_eth_dev_configure, dpdk_found="dpdk", dpdk_found=0)
417	fi
418	if test "$dpdk_found" != 0 -a "$RTE_SDK" != ""; then
419	# Save these now so that they can be re-exported later
420	AC_SUBST([RTE_TARGET])
421	AC_SUBST([RTE_SDK])
422	# Force dpdk library to be statically linked to allow compiler optimisations
423	LIBTRACE_LIBS="$LIBTRACE_LIBS -Wl,--whole-archive -Wl,-l$dpdk_found -Wl,--no-whole-archive -Wl,-lm"
424	AC_DEFINE(HAVE_DPDK,1,[conditional for building with DPDK live capture support])
425	libtrace_dpdk=true
426	fi
427	if test "$RTE_SDK" = ""; then
428	AC_MSG_NOTICE([No RTE_SDK given, checking for system dpdk-dev package])
429	# Search the system, maybe it is installed? Ethdev is one of the main libraries
430	# On Ubuntu and Debian we can simply check for dpdk.so
431	AC_CHECK_LIB(dpdk, rte_eth_dev_configure, dpdk_found="system", dpdk_found=0)
432	# We also need to check that rte.vars.mk is installed from dpdk-dev (as well as libdpdk-dev)
433	if test "$dpdk_found" != 0 -a -e /usr/share/dpdk/mk/rte.vars.mk ; then
434	RTE_TARGET="$(uname -m)-default-linuxapp-gcc"
435	RTE_SDK="/usr/share/dpdk/"
436	RTE_INCLUDE="/usr/include/dpdk"
437	AC_SUBST([RTE_TARGET])
438	AC_SUBST([RTE_SDK])
439	AC_SUBST([RTE_INCLUDE])
440	LIBTRACE_LIBS="$LIBTRACE_LIBS -ldpdk"
441	AC_MSG_NOTICE([Building against system DPDK])
442
443	AC_DEFINE(HAVE_DPDK,1,[conditional for building with DPDK live capture support])
444	libtrace_dpdk=true
445	dpdk_found=system
446	fi
447	fi
448	fi
449
450	# Check for PACKET_FANOUT (borrowed from Suricata)
451	AC_CHECK_DECL([PACKET_FANOUT],
452	AC_DEFINE([HAVE_PACKET_FANOUT],[1],
453	[Recent packet fanout support is available]),
454	[],
455	[[#include <linux/if_packet.h>]])
456
457	# If we use DPDK we might be able to use libnuma
458	AC_CHECK_LIB(numa, numa_node_to_cpus, have_numa=1, have_numa=0)
459
460	# Need libwandder for ETSI live decoding
461	AC_CHECK_LIB(wandder, init_wandder_decoder, have_wandder=1, have_wandder=0)
462
463	# Checks for various "optional" libraries
464	AC_CHECK_LIB(pthread, pthread_create, have_pthread=1, have_pthread=0)
465
466	AC_CHECK_LIB(pthread, pthread_setname_np, have_pthread_setname_np=1, have_pthread_setname_np=0)
467
468	# Check for ncurses
469
470	# These libraries have to be explicitly linked in OpenSolaris
471	AC_SEARCH_LIBS(getservent, socket, have_socket=1, have_socket=0, -lnsl)
472	LIBS=
473
474	AC_SEARCH_LIBS(inet_ntop, nsl, have_nsl=1, have_nsl=0, -lsocket)
475	LIBS=
476
477	# Check to see if we have libdl - *BSD has built-in libdl
478	AC_SEARCH_LIBS(dlopen,dl, dlfound=1,dlfound=0 )
479	LIBS=
480
481	# Check for clock_gettime
482	AC_CHECK_LIB(rt, clock_gettime, have_clock_gettime=1, have_clock_gettime=0)
483	LIBS=
484
485	if test "$have_numa" = 1; then
486	LIBTRACE_LIBS="$LIBTRACE_LIBS -lnuma"
487	AC_DEFINE(HAVE_LIBNUMA, 1, [Set to 1 if libnuma is supported])
488	with_numa=yes
489	else
490	with_numa=no
491	fi
492
493	if test "$have_wandder" = 1; then
494	LIBTRACE_LIBS="$LIBTRACE_LIBS -lwandder"
495	AC_DEFINE(HAVE_WANDDER, 1, [Set to 1 if libwandder is available])
496	wandder_avail=yes
497	else
498	wandder_avail=no
499	fi
500
501	if test "$dlfound" = 0; then
502	AC_MSG_ERROR("Unable to find dlopen. Please use LDFLAGS to specify the location of libdl and re-run configure")
503	fi
504
505	if test "$ac_cv_search_dlopen" != "none required"; then
506	LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_dlopen"
507	if test "$dpdk_found" != 0; then
508	LIBTRACE_LIBS="$LIBTRACE_LIBS -Wl,$ac_cv_search_dlopen"
509	fi
510	fi
511
512	if test "$have_pthread" = 1; then
513	AC_DEFINE(HAVE_LIBPTHREAD, 1, [Set to 1 if pthreads are supported])
514	fi
515
516	if test "$have_pthread_setname_np" = 1; then
517	AC_DEFINE(HAVE_PTHREAD_SETNAME_NP, 1, [Set to 1 if pthread_setname_np is found])
518	fi
519
520	if test "$cryptofound" = 1; then
521	AC_DEFINE(HAVE_LIBCRYPTO, 1, [Set to 1 if libcrypto is available])
522	TOOLS_LIBS="$TOOLS_LIBS -lcrypto"
523	have_crypto=yes
524	else
525	have_crypto=no
526	fi
527
528	if test "$have_nsl" = 1; then
529	if test "$ac_cv_search_inet_ntop" != "none required"; then
530	LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_inet_ntop"
531	LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_inet_ntop"
532	fi
533	fi
534
535	if test "$have_socket" = 1; then
536	if test "$ac_cv_search_getservent" != "none required"; then
537	LIBTRACE_LIBS="$LIBTRACE_LIBS $ac_cv_search_getservent"
538	LIBPKTDUMP_LIBS="$LIBPKTDUMP_LIBS $ac_cv_search_getservent"
539	fi
540	fi
541
542
543	if test "$have_clock_gettime" = 1; then
544	LIBTRACE_LIBS="$LIBTRACE_LIBS -lrt"
545	AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Set to 1 if clock_gettime is supported])
546	with_clock_gettime=yes
547	else
548	with_clock_gettime=no
549	fi
550
551
552	have_memfd_create=no
553	AC_RUN_IFELSE([AC_LANG_PROGRAM([
554	#include <sys/syscall.h>
555	],[
556	#ifndef __NR_memfd_create
557	exit(1)
558	#endif
559	])], [have_memfd_create=yes])
560
561	if test "$have_memfd_create" = "yes"; then
562	AC_DEFINE(HAVE_MEMFD_CREATE, 1, [Set to 1 if kernel supports memfd_create syscall])
563	fi
564
565	# Stupid AC_SEARCH_LIB appends stuff to LIBS even when I don't want it to, so
566	# just set libs to null here to avoid linking against them by default
567	LIBS=
568
569	# For now, the user has to explicitly ask for the LLVM stuff, as it's a bit
570	# rough around the edges :(
571	AC_ARG_WITH([llvm],
572	[AC_HELP_STRING([--with-llvm],
573	[support Just In Time compiler])],
574	use_llvm="yes",
575	use_llvm="no")
576	JIT=no
577
578	# Search for LLVM and the libraries that it requires
579	if (test "$use_llvm" != "no"); then
580	AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
581
582	# XXX Hard coding the path is REALLY bad.
583	# llvm-gcc is installed in a stupid place in Debian / Ubuntu. Hard luck
584	# if you've installed it somewhere custom.
585	# Hopefully in future we can replace this with clang, which may or may
586	# not be installed somewhere intelligent.
587	AC_PATH_PROG(LLVM_GCC, llvm-gcc, no, /usr/lib/llvm/llvm/gcc-4.2/bin)
588
589	AC_LANG_PUSH([C++])
590	AC_CHECK_HEADERS([boost/lexical_cast.hpp], boost="yes", boost="no")
591	AC_LANG_POP([C++])
592
593
594	if test "$boost" = "no"; then
595	AC_MSG_NOTICE([Unabled to find boost libraries. JIT support disabled.])
596	JIT=no
597	elif test "$LLVM_CONFIG" = "no" ; then
598	AC_MSG_NOTICE([Unable to find llvm-config. JIT support disabled.])
599	JIT=no
600	elif test "$LLVM_GCC" = "no"; then
601	AC_MSG_NOTICE([Unable to find llvm-gcc. JIT support disabled.])
602	JIT=no
603	else
604	LIBCXXFLAGS="`$LLVM_CONFIG --cxxflags` $CXXFLAGS"
605	LIBTRACE_LIBS="$LIBTRACE_LIBS `$LLVM_CONFIG --libs all`";
606	LDFLAGS="`$LLVM_CONFIG --ldflags` $LDFLAGS";
607	JIT=yes
608	AC_DEFINE(HAVE_LLVM, 1, [Set to 1 if you have LLVM installed])
609	fi
610	fi
611
612	AC_ARG_WITH([ncurses],
613	AC_HELP_STRING([--with-ncurses], [build tracetop (requires ncurses)]))
614
615	AS_IF([test "x$with_ncurses" != "xno"],
616	[AC_SEARCH_LIBS(mvprintw, ncurses, have_ncurses=yes, have_ncurses=no)
617	LIBS=
618	], [have_ncurses=no])
619
620	AS_IF([test "x$have_ncurses" = "xyes"], [
621	if test "$ac_cv_search_mvprintw" != "none required"; then
622	TOOLS_LIBS="$TOOLS_LIBS $ac_cv_search_mvprintw"
623	fi
624	AC_DEFINE(HAVE_NCURSES, 1, "Compiled with ncurses support")
625	with_ncurses=yes],
626
627
628	[AS_IF([test "x$with_ncurses" = "xyes"],
629	[AC_MSG_ERROR([ncurses requested but not found])])
630	AC_DEFINE(HAVE_NCURSES, 0, "Compiled with ncurses support")
631	with_ncurses=no]
632	)
633
634	# Define automake conditionals for use in our Makefile.am files
635	AM_CONDITIONAL([HAVE_BPF_CAPTURE], [test "$ac_cv_have_decl_BIOCSETIF" = yes ])
636	AM_CONDITIONAL([HAVE_DAG], [test "$libtrace_dag" = true])
637	AM_CONDITIONAL([HAVE_DPDK], [test "$libtrace_dpdk" = true])
638	AM_CONDITIONAL([HAVE_WANDDER], [test "x$wandder_avail" = "xyes"])
639	AM_CONDITIONAL([DAG2_4], [test "$libtrace_dag_version" = 24])
640	AM_CONDITIONAL([DAG2_5], [test "$libtrace_dag_version" = 25])
641	AM_CONDITIONAL([HAVE_NETPACKET_PACKET_H], [test "$libtrace_netpacket_packet_h" = true])
642	AM_CONDITIONAL([HAVE_LIBGDC], [test "$ac_cv_header_gdc_h" = yes])
643	AM_CONDITIONAL([HAVE_LLVM], [test "x$JIT" != "xno" ])
644	AM_CONDITIONAL([HAVE_NCURSES], [test "x$with_ncurses" != "xno"])
645
646	# Check for miscellaneous programs
647	AC_CHECK_PROG([libtrace_doxygen], [doxygen], [true], [false])
648
649	AM_CONDITIONAL(HAS_DOXYGEN, [test x"$libtrace_doxygen" = xtrue])
650
651	# Set all our output variables
652	AC_SUBST([LIBTRACE_LIBS])
653	AC_SUBST([LIBPKTDUMP_LIBS])
654	AC_SUBST([TOOLS_LIBS])
655	#AC_SUBST([ADD_LIBS])
656	AC_SUBST([ADD_LDFLAGS])
657	AC_SUBST([ADD_INCLS])
658	AC_SUBST([LTLIBOBJS])
659	AC_SUBST([MANPAGES])
660	AC_SUBST([PACKAGE_VERSION])
661	AC_SUBST([LIBTRACE_MAJOR])
662	AC_SUBST([LIBTRACE_MID])
663	AC_SUBST([LIBTRACE_MINOR])
664	AC_SUBST([DAG_VERSION_NUM])
665	AC_SUBST([HAVE_BPF_CAPTURE])
666	AC_SUBST([HAVE_LIBGDC])
667	AC_SUBST([HAVE_LLVM])
668	AC_SUBST([HAVE_NCURSES])
669	AC_SUBST([LIBCFLAGS])
670	AC_SUBST([LIBCXXFLAGS])
671
672
673	# Finally, output our Makefiles
674	AC_OUTPUT
675
676	# Function for reporting whether an option was set or not
677	reportopt() {
678	if test x"$2" = xtrue -o x"$2" = xyes; then
679	AC_MSG_NOTICE([$1: Yes])
680	else
681	AC_MSG_NOTICE([$1: No])
682	fi
683	}
684
685
686	# Report which configure options were set
687	echo
688	AC_MSG_NOTICE([Libtrace version $PACKAGE_VERSION])
689	if test "$pcapcreate" = 1; then
690	AC_MSG_NOTICE([Compiled with PCAP support: >= 1.0])
691	else
692	AC_MSG_NOTICE([Compiled with PCAP support: < 1.0])
693	fi
694
695	if test x"$libtrace_dag" = xtrue; then
696	if test "$libtrace_dag_version" = 24; then
697	AC_MSG_NOTICE([Compiled with DAG live capture support: 2.4])
698	elif test "$libtrace_dag_version" = 30; then
699	AC_MSG_NOTICE([Compiled with DAG live capture support: 3.0])
700	else
701	AC_MSG_NOTICE([Compiled with DAG live capture support: 2.5])
702	fi
703	else
704	AC_MSG_NOTICE([Compiled with DAG live capture support: No])
705	fi
706
707	if test x"$libtrace_dpdk" = xtrue; then
708	AC_MSG_NOTICE([Compiled with DPDK live capture support: Yes])
709	reportopt "Compiled with DPDK trace NUMA support" $with_numa
710	reportopt "Compiled with clock_gettime support" $with_clock_gettime
711	elif test x"$want_dpdk" != "xno"; then
712	# We don't officially support DPDK so only report failure if the user
713	# explicitly asked for DPDK. That way, we can hopefully keep it hidden
714	# from most users for now...
715
716	AC_MSG_NOTICE([Compiled with DPDK live capture support: No])
717	AC_MSG_NOTICE([Note: Requires DPDK v1.5 or newer])
718	fi
719	reportopt "Compiled with LLVM BPF JIT support" $JIT
720	reportopt "Compiled with live ETSI LI support (requires libwandder)" $wandder_avail
721	reportopt "Building man pages/documentation" $libtrace_doxygen
722	reportopt "Building tracetop (requires libncurses)" $with_ncurses
723	reportopt "Building traceanon with CryptoPan (requires libcrypto and openssl/evp.h)" $have_crypto
724
725	# Report any errors relating to missing bison, flex, etc.
726	echo
727	ac_cv_errcount=0;
728	if test -z "$YACC"; then
729	AC_MSG_WARN(bison or yacc not found. Please install bison before continuing)
730	ac_cv_errcount=$((ac_cv_errcount + 1))
731	fi
732
733	if test "x$LEX" != xflex -a "x$LEX" != xlex; then
734	AC_MSG_WARN(flex or lex not found. Please install flex before continuing)
735	ac_cv_errcount=$((ac_cv_errcount + 1))
736	fi
737
738	if test $ac_cv_errcount -gt 0; then
739	AC_MSG_ERROR(Critical packages are missing and compilation will fail. Please install the packages listed above and rerun ./configure)
740	fi
741

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format